SAP ABAP Help

Moved to Own domain..!

2011-09-07T21:43:00.000-05:00

Hello All,

Over the past couple of months, I was thinking to move SAP ABAP Help blog to its own domain. Finally, I have decided to move it to domain: www.help-abap.zevolving.com

This new site would have lot of NEW features:

New sections: Beginners(as highly demanded), Design Patterns & Design Principles, IDOC, performance and many more...
More Social Sharing: Social sharing including Facebook alongwith RSS and Twitter
Syntax Highlighter: "New" ABAP Editor like syntax highlighter with Interactive toolbar
Improved Comments: Reply option to start discussion on any comment
Suggestions: Suggestion page for better feedback regarding site layout and content
Mobile Version: Mobile device compatible version

(Some are already implemented, rest would be available soon)

Friends using the Google Friend Connect:
I couldn't find any good technique to migrate you from Blogger to the new site. I personally request you to use the RSS Feed Subscription to get all the updates in your email. I have included couple of options here for hassle-free Email Subscription.

Subscribe to SAP ABAP Help by Email

Please explore this new SAP ABAP Help and let me know about your feedback via Suggestion page.

Regards,
Naimesh Patel

Chrome Extension for SAP ABAP Blog

2011-07-15T18:22:00.010-05:00

I am proud to present first version of Chrome Extension for SAP ABAP Help Blog. This extension is also the first one SAP space. SAP ABAP Help extension is now available in the Chrome Web Store. This extension allow you to stay tuned with the Blog content - Both Post and Comments.

If you are not yet using Chrome browser, you can install it by visiting Chrome Download page.

After you install the extension, you would see this icon in the Chrome browser.

By clicking this icon, you will observe a popup with the latest post, latest comment and popular posts.

You can configure the number of posts, displaying author & post date as well as the Summary for the post. Similar type of settings are also available for comments section. Settings can be accessed using this option.

Let me know if you face any issues while using the extension.

Enjoy another way to stay in touch with SAP ABAP Blog...

Get in touch with me if you wish to know, how this works or want to develop one for your site/blog.

Function Module Pass by Value - Data Loss

2011-06-20T21:40:00.017-05:00

When we design the Function Module, we can specify either Pass by Value or Pass by Reference for a parameter. It is very important to pay close attention while designing the FM where we are using the Table Types as the variables.

Have you ever seen a situation where you can see the data in internal table but it doesn't LOOP further. It exits out of the LOOP and only processes that LOOP only. Sounds weird?

Let's see this code. We have an ITAB which has 5 records. We pass this ITAB to the FM ZTEST_NP_PASS_BY_VALUE as parameter CT_VBAP. This parameter is Pass by Value. In the FM, we copy the data from the importing parameter to local table LT_VBAP. We Sort the table LT_VBAP and delete adjacent duplicates which would leave only one record in the LT_VBAP. Ideally, it should not change anything in the CT_VBAP. But the output is surprising.

*&---------------------------------------------------------------------*

*&  Purpose: Illustrates dangerous use of Pass by Value

*&  Author : Naimesh Patel

*&---------------------------------------------------------------------*



REPORT  ztest_np_itab_copy.



DATA: lt_vbap TYPE STANDARD TABLE OF vbap.

DATA: lv_index TYPE i.



*PARAMETERS: p_vbeln TYPE vbak-vbeln DEFAULT '1001234567'.



START-OF-SELECTION.



*----- Pass by Value --------*

PERFORM f_fill_data.



WRITE: / 'Pass by Value'.

WRITE: /(5) space, 'Total lines in LT_VBAP'.

LOOP AT lt_vbap TRANSPORTING NO FIELDS WHERE vbeln IS NOT INITIAL.

WRITE: / sy-tabix.

ENDLOOP.



WRITE: /(5) space, 'FM Call - Parameter Pass by Value'.

LOOP AT lt_vbap TRANSPORTING NO FIELDS WHERE vbeln IS NOT INITIAL.

WRITE : /(10) space, 'Processing', sy-tabix.

CALL FUNCTION 'ZTEST_NP_PASS_BY_VALUE'

CHANGING

ct_vbap = lt_vbap.

ENDLOOP.



* Total Lines

lv_index = LINES( lt_vbap ).

WRITE: /(5) space, 'Total lines in LT_VBAP', lv_index.





*&---------------------------------------------------------------------*

*&      Form  F_FILL_DATA

*&---------------------------------------------------------------------*

FORM f_fill_data .



DATA: lwa_vbap LIKE LINE OF lt_vbap.

DATA: l_vbeln TYPE vbak-vbeln.

l_vbeln = '1001234567'.

DO 5 TIMES.

lwa_vbap-vbeln = l_vbeln.

lwa_vbap-posnr = sy-index * 100.

APPEND lwa_vbap TO lt_vbap.

ENDDO.



ENDFORM.                    " F_FILL_DATA

This is the FM ZTEST_NP_PASS_BY_VALUE:

FUNCTION ZTEST_NP_PASS_BY_VALUE.

*"----------------------------------------------------------------------

*"*"Local Interface:

*"  CHANGING

*"     VALUE(CT_VBAP) TYPE  VBAP_T

*"----------------------------------------------------------------------



DATA: li_vbap TYPE STANDARD TABLE OF vbap.

li_vbap = ct_vbap.



SORT li_vbap BY vbeln.

DELETE ADJACENT DUPLICATES FROM li_vbap COMPARING vbeln.



ENDFUNCTION.

Here is the output of the above code:
You can see that there are 5 lines in the LT_VBAP. After FM was called for the first record, it didn't LOOP further. But the total number of lines in the table LT_VBAP are still 5.

What happened here:
Till the statement which copies the data from the CT_VBAP to LI_VBAP, it is referring to same memory reference which can be checked in the debugger. Once the FM passes control back to the called program, some how it is loosing the track of the T_VBAP and put the data from LI_VBAP back to T_VBAP which has essentially only 1 record. It is weird that the Debugger also shows that still T_VBAP has 5 rows. But the LOOP finishes after processing the 1st record as seen in the output of the report.

Impact
Imagine if this type of FM call with Pass by Value is in the User-exit which could be deep down burried in the call stack and LOOP doesn't processes all the records in the starndard SAP code, it would be pretty difficult to figure out what happend and why it was happened.

How to save this data from Data Loss?
We need to use the table with reference. This avoid us loosing the data and keeps the data consistency.

Code Snippet to demo pass by Reference

*----- Pass by Reference ---- *

SKIP 2.

CLEAR lt_vbap.

PERFORM f_fill_data.



WRITE: / 'Pass by Reference'.

WRITE: /(5) space, 'Total lines in LT_VBAP'.

LOOP AT lt_vbap TRANSPORTING NO FIELDS WHERE vbeln IS NOT INITIAL.

WRITE: / sy-tabix.

ENDLOOP.



WRITE: /(5) space, 'FM Call - Parameter with Reference'.

LOOP AT lt_vbap TRANSPORTING NO FIELDS WHERE vbeln IS NOT INITIAL.

WRITE : /(10) space, 'Processing', sy-tabix.

CALL FUNCTION 'ZTEST_NP_REFERENCE'

CHANGING

ct_vbap = lt_vbap.

ENDLOOP.



* Total Lines

lv_index = LINES( lt_vbap ).

WRITE: /(5) space, 'Total lines in LT_VBAP', lv_index.

Code Snippet FM ZTEST_NP_REFERENCE

FUNCTION ztest_np_reference.

*"----------------------------------------------------------------------

*"*"Local Interface:

*"  CHANGING

*"     REFERENCE(CT_VBAP) TYPE  VBAP_T

*"----------------------------------------------------------------------



DATA: lt_vbap TYPE STANDARD TABLE OF vbap.

lt_vbap = ct_vbap.



SORT lt_vbap BY vbeln.

DELETE ADJACENT DUPLICATES FROM lt_vbap COMPARING vbeln.

ENDFUNCTION.

Output of this code:

Performance of ITAB Copy

2011-06-13T19:14:00.023-05:00

Today, we'll see another performance drainage - Internal Table Copy. If we don't use the data properly, we'll run into the situation where we'll use lot of resoruces to perform the ITAB copy and end up reducing the performance of our application.

Sometimes, we pass the ITAB from one application to diffrent FM / Method, do some processing like modify certain fields or add some records in it and we get it back from the called module. If this FMs are called so many times it will affect the application performace at large.

We'll first try to copy the data traditionally - using []. In the main program we have an internal table, which we pass to the FM ZTEST_NP_DATA_SET. Here we save the data to global memory of the Function Group into IT_EDIDD. We'll call another FM ZTEST_NP_DATA_GET to get the data.

The second way, we'll use the REF TO DATA. from our main program, we'll get the reference of the data into O_DATA and pass it to FM ZTEST_NP_DATA_SET_1. We'll get the data from the object reference. We'll aslo save the data reference to the Function group Global data. We'll call the FM ZTEST_NP_DATA_SET_2 to get the data from the FM to main program.

Code Snippet to show performance of ITAB Copy

*&---------------------------------------------------------------------*

*& Performance of ITAB Copy 

*& Author: Naimesh Patel

*&---------------------------------------------------------------------*



REPORT  ztest_np_itab_copy.



DATA: lt_edidd TYPE STANDARD TABLE OF edid4.

DATA: lwa_edidd LIKE LINE OF lt_edidd.



DATA: lv_sta_time TYPE timestampl,

      lv_end_time TYPE timestampl,

      lv_diff_w   TYPE p DECIMALS 5,

      lv_diff_f   LIKE lv_diff_w,

      lv_save     LIKE lv_diff_w.



DATA: l_times TYPE i.



START-OF-SELECTION.



  l_times = 10000.



* Table copy with []

  GET TIME STAMP FIELD lv_sta_time.

  DO l_times TIMES.

    lwa_edidd-sdata = '1'.

    APPEND lwa_edidd TO lt_edidd.



    CALL FUNCTION 'ZTEST_NP_DATA_SET'

      EXPORTING

        it_edidd = lt_edidd.



    CALL FUNCTION 'ZTEST_NP_DATA_GET'

      IMPORTING

        et_edidd = lt_edidd.

  ENDDO.

  GET TIME STAMP FIELD lv_end_time.

  lv_diff_w = lv_end_time - lv_sta_time.

  WRITE: /(30) 'Itab Copy', lv_diff_w.



* table passed with reference

  CLEAR lt_edidd.

  DATA: lo_data TYPE REF TO data.

  GET TIME STAMP FIELD lv_sta_time.

  DO l_times TIMES.

    lwa_edidd-sdata = '1'.

    APPEND lwa_edidd TO lt_edidd.



    GET REFERENCE OF lt_edidd INTO lo_data.



    CALL FUNCTION 'ZTEST_NP_DATA_SET_1'

      EXPORTING

        io_edidd = lo_data.



    CALL FUNCTION 'ZTEST_NP_DATA_GET_1'

      IMPORTING

        eo_edidd = lo_data.



  ENDDO.

  GET TIME STAMP FIELD lv_end_time.

  lv_diff_f = lv_end_time - lv_sta_time.

  WRITE: /(30) 'Itab Copy with Reference', lv_diff_f.

Code FM ZTEST_NP_DATA_SET Data Copy using [ ]

FUNCTION ZTEST_NP_DATA_SET.

*"----------------------------------------------------------------------

*"*"Local Interface:

*"  IMPORTING

*"     VALUE(IT_EDIDD) TYPE  TAB_EDIDD

*"----------------------------------------------------------------------



  t_edidd[] = it_edidd[].





  data: lwa_edidd like line of t_edidd.

  if lines( t_edidd ) = 500.

    append lwa_edidd to t_edidd.

  ENDIF.



ENDFUNCTION.

Code FM ZTEST_NP_DATA_GET to data from FG

FUNCTION ZTEST_NP_DATA_GET.

*"----------------------------------------------------------------------

*"*"Local Interface:

*"  EXPORTING

*"     REFERENCE(ET_EDIDD) TYPE  TAB_EDIDD

*"----------------------------------------------------------------------



  et_edidd = t_edidd.



ENDFUNCTION.

Code FM ZTEST_NP_DATA_SET_1 - Data copy using REF TO DATA

FUNCTION ztest_np_data_set_1.

*"----------------------------------------------------------------------

*"*"Local Interface:

*"  IMPORTING

*"     REFERENCE(IO_EDIDD) TYPE REF TO  DATA

*"----------------------------------------------------------------------



  o_edidd = io_edidd.



  FIELD-SYMBOLS: <lt_edidd> TYPE tab_edidd.



  ASSIGN o_edidd->* TO <lt_edidd>.

  DATA: lwa_edidd LIKE LINE OF <lt_edidd>.



  IF LINES( <lt_edidd> ) = 500.

    APPEND lwa_edidd TO <lt_edidd>.

  ENDIF.





ENDFUNCTION.

Code ZTEST_NP_DATA_GET_1 - Get Data reference back

FUNCTION ZTEST_NP_DATA_GET_1.

*"----------------------------------------------------------------------

*"*"Local Interface:

*"  EXPORTING

*"     REFERENCE(EO_EDIDD) TYPE REF TO  DATA

*"----------------------------------------------------------------------



  eo_edidd = o_edidd.



ENDFUNCTION.

Some stats on running the program with different number of records:

On graph:

So, if we use the traditional ITAB Copy, it will decrease the performance with increasing number of records.

READ-ONLY attribute vs GETTER methods

2011-02-22T20:08:00.020-06:00

READ-ONLY is something different for the people who have worked on the OOP in the past. Like JAVA doesn't have the read only addition. So, there is a hot discussion going on in SAP ABAP Objects world, why READ-ONLY is there and what is the purpose of it. Let's unleash the READ-ONLY (and its power over GETTER methods).

As good Object Oriented Programming suggests, we should hide our attributes from the outside world and let them allow to access only with the PUBLIC methods. These methods are:

SETTER – To set the data to the attribute. Usually, this method has the single parameter and typically that is named as VALUE. Implementation of the method sets the respective attribute from the parameter value. So, we should use the naming convention as SET_attr( ).

GETTER – To retrieve the value from the attribute. This method should have the single parameter and typically it would be VALUE as type RETURNING. Implementation of this method, passes the attribute value to the caller in the parameter. As we name the SETTER methods, we should name the GETTER methods as GET_attr( ).

Now, let’s see what is the READ-ONLY:
READ-ONLY is the addition to the PUBLIC attributes. This allows the caller to access the attribute, but doesn’t allow it to change the value. Refer keyword documentation on READ-ONLY on SAP Help at: READ-ONLY addition

Caller can simply access the variable directly with proper operator. Like this:

Caller accesses READ-ONLY attribute

*&---------------------------------------------------------------------*
*& Developer : Naimesh Patel
*& Purpose   : READ-ONLY Demo
*&---------------------------------------------------------------------*
REPORT  ztest_np.
*
CLASS lcl_example DEFINITION.
  PUBLIC SECTION.
    DATA: v_speed TYPE i READ-ONLY.
    METHODS:
      constructor IMPORTING speed TYPE i.
ENDCLASS.                    "lcl_example DEFINITION
*
CLASS lcl_example IMPLEMENTATION.
  METHOD constructor.
    me->v_speed = speed.
  ENDMETHOD.                    "constructor
ENDCLASS.                    "lcl_example IMPLEMENTATION

START-OF-SELECTION.
  DATA: o_test TYPE REF TO lcl_example.
  CREATE OBJECT o_test
    EXPORTING
      speed = 10.
* o_test->v_speed = 100.    " Syntax Error
  WRITE: 'Accessing V_SPEED:', o_test->v_speed.

In simple terms, we can reduce the amount of coding by using the READ-ONLY operator rather than creating GET_attr( ) methods for each methods.

GETTER vs READ-ONLY Performance: Who wins?
I tried to create this sample program to find out which is better. Here is the code lines:

Code Lines for READ-ONLY vs GETTER

*&---------------------------------------------------------------------*
*& Developer : Naimesh Patel
*& Purpose   : READ-ONLY vs GETTER Performance
*&---------------------------------------------------------------------*
REPORT  ztest_np.
*
CLASS lcl_car DEFINITION.
  PUBLIC SECTION.
    DATA: v_speed TYPE i READ-ONLY.
    METHODS: get_speed RETURNING value(return) TYPE i.
    METHODS: set_speed IMPORTING value TYPE i.
ENDCLASS.                    "lcl_car DEFINITION

*
CLASS lcl_car IMPLEMENTATION.
  METHOD get_speed.
    return = v_speed.
  ENDMETHOD.                    "get_speed
  METHOD set_speed.
    v_speed = value.
  ENDMETHOD.                    "set_speed
ENDCLASS.                    "lcl_Car IMPLEMENTATION

START-OF-SELECTION.
  DATA: o_bmw TYPE REF TO lcl_car.
  CREATE OBJECT o_bmw.
  DATA: lv_speed TYPE i.
  DATA: lv_temp TYPE i.

  DATA: lv_flag TYPE flag,
        lv_sta_time TYPE timestampl,
        lv_end_time TYPE timestampl,
        lv_diff_w   TYPE p DECIMALS 5,
        lv_diff_f   LIKE lv_diff_w,
        lv_save     LIKE lv_diff_w.

* Getter Performance
  GET TIME STAMP FIELD lv_sta_time.
  DO 1000 TIMES.
    o_bmw->set_speed( sy-index ).
    lv_temp = lv_temp + o_bmw->get_speed( ).
  ENDDO.
  GET TIME STAMP FIELD lv_end_time.
  lv_diff_w = lv_end_time - lv_sta_time.
  WRITE: /(15) 'With getter', lv_diff_w.

  CLEAR: lv_sta_time, lv_end_time, lv_temp.

* READ-ONLY Performance
  GET TIME STAMP FIELD lv_sta_time.
  DO 1000 TIMES.
    o_bmw->set_speed( sy-index ).
    lv_temp = lv_temp + o_bmw->v_speed.
  ENDDO.
  GET TIME STAMP FIELD lv_end_time.
  lv_diff_f = lv_end_time - lv_sta_time.
  WRITE: /(15) 'With READ-ONLY', lv_diff_f.

* Saved time
  lv_save = lv_diff_w - lv_diff_f.
  WRITE: /(15) 'Saved time', lv_save.

When I ran the report, it showed that we can save around 67% of time while using the READ-ONLY compared to GETTER( ) method. When GETTER( ) method take about 100% time, direct attribute access finishes job in about 33% time. This should be useful when we are designing complex system, which uses too many GETTER methods.

CLASS_CONSTRUCTOR and CONSTRUCTOR: Who comes before whom?

2011-02-17T20:18:00.013-06:00

Today we will see how the constructor and class-constructor triggers at runtime. Before we start, please complete the survey as per my previous post - SAP ABAP Help needs your HELP!!, if you hadn't (Thanks).

CONSTRUCTOR
Whenever we instantiate the object using the statement CREATE OBJECT statement, CONSTRUCTOR would be called. System creates an object before it calls the CONSTRUCTOR method.

CLASS_CONSTRUCTOR
This type of constructor is the static constructor. This would be automatically accessed when system accesses the class for the first time.

CONSTRUCTOR( ) is called when we instantiate the object, whereas call of CLASS_CONSTRUCTOR( ) method is different based how the class is accessed. Let's see it in details using this Classes.

Class Hierarchy UML -
Each of this class has a CONSTRUCTOR( ), a CLASS-CONSTRUCTOR( ) and a Constant except class LCL_C.

Code Snippet

  
*&---------------------------------------------------------------------*
*& Developer : Naimesh Patel
*& Purpose   : CLASS_CONSTRUCTOR and CONSTRUCTOR explaination
*&---------------------------------------------------------------------*
*
REPORT  ZTEST_NP.
*
* ==== LCL_A ===== *
*
CLASS lcl_a DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS: class_constructor.
    CONSTANTS: c_a TYPE char1 VALUE 'A'.
    METHODS: constructor.
ENDCLASS.                    "lcl_a DEFINITION
*
CLASS lcl_a IMPLEMENTATION.
  METHOD class_constructor.
    WRITE: / ' Class Constructor A'.
  ENDMETHOD.                    "class_constructor
  METHOD constructor.
    WRITE: / '  Constructor A'.
  ENDMETHOD.                    "constructor
ENDCLASS.                    "lcl_a IMPLEMENTATION
*
* ==== LCL_B ===== *
*
CLASS lcl_b DEFINITION INHERITING FROM lcl_a.
  PUBLIC SECTION.
    CONSTANTS: c_b TYPE char1 VALUE 'B'.
    CLASS-METHODS: class_constructor.
    METHODS constructor.
ENDCLASS.                    "lcl_b DEFINITION
*
CLASS lcl_b IMPLEMENTATION.
  METHOD class_constructor.
    WRITE : / ' Class Constructor B'.
  ENDMETHOD.                    "class_constructor
  METHOD constructor.
    super->constructor( ).
    WRITE : / '  Constructor B'.
  ENDMETHOD.                    "constructor
ENDCLASS.                    "lcl_b IMPLEMENTATION
*
* ==== LCL_C ===== *
*
CLASS lcl_c DEFINITION INHERITING FROM lcl_b.
  PUBLIC SECTION.
    CLASS-METHODS: class_constructor.
    METHODS constructor.
ENDCLASS.                    "lcl_b DEFINITION
*
CLASS lcl_c IMPLEMENTATION.
  METHOD class_constructor.
    WRITE : / ' Class Constructor C'.
  ENDMETHOD.                    "class_constructor
  METHOD constructor.
    super->constructor( ).
    WRITE : / '  Constructor C'.
  ENDMETHOD.                    "constructor
ENDCLASS.                    "lcl_b IMPLEMENTATION
*
* ==== LCL_D ===== *
*
CLASS lcl_d DEFINITION INHERITING FROM lcl_c.
  PUBLIC SECTION.
    CONSTANTS: c_d TYPE char1 VALUE 'D'.
    CLASS-METHODS: class_constructor.
    METHODS constructor.
ENDCLASS.                    "lcl_b DEFINITION
*
CLASS lcl_d IMPLEMENTATION.
  METHOD class_constructor.
    WRITE : / ' Class Constructor D'.
  ENDMETHOD.                    "class_constructor
  METHOD constructor.
    super->constructor( ).
    WRITE : / '  Constructor D'.
  ENDMETHOD.                    "constructor
ENDCLASS.                    "lcl_b IMPLEMENTATION
*
* ==== LCL_Z ===== *
*
CLASS lcl_z DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS: class_constructor.
    CONSTANTS: c_z TYPE char1 VALUE 'Z'.
    METHODS: constructor.
ENDCLASS.                    "lcl_z DEFINITION
*
CLASS lcl_z IMPLEMENTATION.
  METHOD class_constructor.
    WRITE: / ' Class Constructor Z'.
  ENDMETHOD.                    "class_constructor
  METHOD constructor.
    WRITE: / '  Constructor Z'.
  ENDMETHOD.                    "constructor
ENDCLASS.                    "lcl_z IMPLEMENTATION

Now, let's take a look at different scenarios:
This code accesses the constant C_D of the class LCL_D.

Code Snippet - Constant access Scenario

  
LOAD-OF-PROGRAM.
  WRITE: / '... LOAD-OF-PROGRAM ...'.
*
START-OF-SELECTION.
  SKIP 2.
  WRITE: / '... START-OF-SELECTION ...'.
  WRITE: / 'lcl_d=>c_d  ..... ', lcl_d=>c_d.

It has executed all the CLASS_CONSTRUCTOR( ) of the higher classes in class hierarchy of class D i.e. Class LCL_A, LCL_B, LCL_C and LCL_D in the sequence. It didn't execute the CLASS_CONSTRUCTOR( ) of the Class LCL_Z because we are not referring to any component of that class.

Second scenario, in which we instantiate the object reference to LCL_D.

Code Snippet - Instantiation scenario

  
LOAD-OF-PROGRAM.
  WRITE: / '... LOAD-OF-PROGRAM ...'.
*
START-OF-SELECTION.
  SKIP 2.
  WRITE: / '... START-OF-SELECTION ...'.
  WRITE: / 'Instantiating LO_D'.
  DATA: lo_d TYPE REF TO lcl_d.
  CREATE OBJECT lo_d.

We can see that the CLASS_CONSTRUCTOR and CONSTRUCTOR were not called before START-OF-SELECTION. They were actually called when the CREATE OBJECT statement reached. So, instantiating the object has first called the method CLASS_CONSTRUCTOR( ) of the higher classes in the class hierarchy and then all CONSTRUCTOR( ).

Which class-constructor calls first when both classes are not related?

Code Snippet - Complex

  
LOAD-OF-PROGRAM.
  WRITE: / '... LOAD-OF-PROGRAM ...'.
*
START-OF-SELECTION.
  SKIP 2.
  WRITE: / '... START-OF-SELECTION ...'.
  WRITE: / 'Instantiating LO_D'.
  DATA: lo_d TYPE REF TO lcl_d.
  CREATE OBJECT lo_d.
*
  SKIP 1.
  WRITE: / 'lcl_z=>c_z  ..... ', lcl_z=>c_z.
  WRITE: / 'lcl_b=>c_b  ..... ', lcl_b=>c_b.

Wow! Too many different execution paths! System first encountered LCL_Z=>C_Z. So, it has called the CLASS_CONSTRUCTOR of the LCL_Z. After that it encountered LCL_B=>C_B. Thus, it calls the CLASS_CONSTRUCTOR of the class hierarchy of the class LCL_B i.e. CLASS_CONSTRUCTOR of classes LCL_A and LCL_B.

Now, when we instantiated the object LO_D, system calls the methods CLASS_CONSTRUCTOR( ) of the remaining classes of the class hierarchies i.e. method CLASS_CONSTRUCTOR( ) of classes LCL_C and LCL_D. It doesn't call CLASS_CONSTRUCTOR( ) of the classes LCL_A and LCL_B, because they were already called when it has encountered the access to constant LCL_B=>C_B.

You can find more information of constructors on SAP Keyword documentation - Constructors

SAP ABAP Help needs your HELP!!

2011-02-16T21:02:00.010-06:00

I need your help to improve the content on this site, like content of the site, look & feel, etc.

I had setup a survey. Please take this survey - SAP ABAP Help Survey. It will only take 5 minutes of your time. You can also leave comment here, if you wish to have something which is not listed in the survey.

If somehow this link doesn't work, please leave a comment here. I'll try to fix it.

Thanks Much! I Appreciate your help!

Regards,
Naimesh Patel

Generic Object Services (GOS) Toolbar Part 7 : Relationship Browser

2010-11-18T22:09:00.017-06:00

Relationships in GOS Toolbar

In the series of Generic Object Services(GOS) available in the SAP, we have discussed different usage of the GOS toolbar. You can find all of these discussions at Tutorials > Generic Object Services (GOS).

Today, we'll see the another concept: Relationship browser. Relationships option is available in the GOS Toolbar at GOS toolbar > Relationships.

This browser could display different linked objects like Sales Documents, Inbound IDOCs, Outbound IDOcs etc.

Now lets see how to add this Relationships in this relationship browser. For this purpose, we can use method CREATE_LINK of the class CL_BINARY_RELATION or the FM BINARY_RELATION_CREATE.

Method CREATE_LINK is an advanced version to create the Link which would be displayed in the Relationship browser. Since the method CREATE_LINK is an improved version to create the links, it doesn't support all the object models. For the remaining of the object models, we need to use the FM BINARY_RELATION_CREATE. So, the question is how to know when to use FM.

When the relation model is not supported by the method CREATE_LINK, it raises the exception CX_OBL_MODEL_ERROR. So, we'll call the method CREATE_LINK inside the TRY ... CATCH ... ENDTRY block.

This Code Snippet shows how to use the method to create links in the relationship browser.

*&---------------------------------------------------------------------*

*& Developer: Naimesh Patel

*& Purpose  : To Create Relation between Business Objects

*&---------------------------------------------------------------------*

REPORT  zgos_relation_create.

*

*

CLASS lcl_relation DEFINITION.

  PUBLIC SECTION.

    TYPES:

      BEGIN OF ty_related.

            INCLUDE TYPE sibflporb.

    TYPES:

        relation TYPE oblreltype,

      END   OF ty_related.

    TYPES:

      ty_t_related TYPE STANDARD TABLE OF ty_related.

    METHODS:

      constructor

        IMPORTING

          obj_no   TYPE sibfboriid

          obj_type TYPE sibftypeid

          obj_cat  TYPE sibfcatid.

    METHODS:

      add_relation

        IMPORTING

          obj_no   TYPE sibfboriid

          obj_type TYPE sibftypeid

          obj_cat  TYPE sibfcatid

          relation TYPE oblreltype.

    METHODS:

      create_relations.

  PRIVATE SECTION.

    DATA:

      t_related TYPE ty_t_related,  "sibflporbt,

      my_prop   TYPE sibflporb.

ENDCLASS.                    "lcl_relation DEFINITION

*

*

CLASS lcl_relation IMPLEMENTATION.

  METHOD constructor.

*   Set Properties of Referent

    me->my_prop-instid = obj_no.

    me->my_prop-typeid = obj_type.

    me->my_prop-catid  = obj_cat.

  ENDMETHOD.                    "constructor

  METHOD add_relation.

*   Add Referenc

    FIELD-SYMBOLS: <lfs_relat> LIKE LINE OF me->t_related.

    APPEND INITIAL LINE TO me->t_related ASSIGNING <lfs_relat>.

    <lfs_relat>-instid = obj_no.

    <lfs_relat>-typeid = obj_type.

    <lfs_relat>-catid  = obj_cat.

    <lfs_relat>-relation = relation.

  ENDMETHOD.                    "add_relation

*

  METHOD create_relations.

    DATA: lwa_relate_key TYPE sibflporb.

    FIELD-SYMBOLS: <lfs_relat> LIKE LINE OF me->t_related.

*

    DATA:

      ls_parent   TYPE borident,

      ls_related  TYPE borident,

      lv_relation TYPE binreltyp,

      lx_obl    TYPE REF TO cx_obl,

      lp_errstr TYPE string,

      lv_done TYPE flag.

*

*   for each relation

    LOOP AT me->t_related ASSIGNING <lfs_relat>.

      MOVE-CORRESPONDING <lfs_relat> TO lwa_relate_key.

      TRY.

*      First try with new method to create the Link

          CALL METHOD cl_binary_relation=>create_link

            EXPORTING

              is_object_a = my_prop

              is_object_b = lwa_relate_key

              ip_reltype  = <lfs_relat>-relation.

*

          lv_done = 'X'.

*

*       If the Link can not be handled by this class, call the

*       FM to create the link

        CATCH cx_obl_model_error.

*

          ls_parent-objkey  = me->my_prop-instid.

          ls_parent-objtype = me->my_prop-typeid.

          ls_related-objkey  = <lfs_relat>-instid.

          ls_related-objtype = <lfs_relat>-typeid.

          lv_relation = <lfs_relat>-relation.

*

          CALL FUNCTION 'BINARY_RELATION_CREATE'

            EXPORTING

              obj_rolea      = ls_parent

              obj_roleb      = ls_related

              relationtype   = lv_relation

            EXCEPTIONS

              no_model       = 1

              internal_error = 2

              unknown        = 3

              OTHERS         = 4.

          IF sy-subrc <> 0.

            MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno

                    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.

          ELSE.

            lv_done = 'X'.

          ENDIF.

        CATCH cx_obl INTO lx_obl.

          lp_errstr = lx_obl->get_text( ).

          MESSAGE lp_errstr TYPE 'S'.

      ENDTRY.

*

      IF lv_done = 'X'.

        WRITE: / 'Relation added: ', <lfs_relat>-instid(10), <lfs_relat>-relation.

      ENDIF.

*

    ENDLOOP.

*

    COMMIT WORK.

*

  ENDMETHOD.                    "create_relations

ENDCLASS.                    "lcl_relation IMPLEMENTATION

*

START-OF-SELECTION.

  DATA: o_relation TYPE REF TO lcl_relation.

*

* Sales Order as the Referent

  CREATE OBJECT o_relation

    EXPORTING

      obj_no   = '1000010010'        " Sales Order Number

      obj_type = 'BUS2032'           " Sales Order

      obj_cat  = 'BO'.

*

* Add Delivery to Sales Order

  o_relation->add_relation(

    obj_no   = '8000020000'

    obj_type = 'LIKP'

    obj_cat  = 'BO'

    relation = 'LINK' ).             " Link

*

* Add IDOC to Sales Order

  o_relation->add_relation(

    obj_no   = '1000012345'

    obj_type = 'IDOC'

    obj_cat  = 'BO'

    relation = 'IDC0' ).             " IDOC

*

* Create Relations

  o_relation->create_relations( ).

After successful program run, it will display the relationship in the browser of the Order.

Generic Object Services (GOS) Toolbar Part 6 : Copy Attachments between objects

2010-11-17T21:06:00.004-06:00

Copy GOS attachment from one object to another object

Sometimes it is required to copy the attachments from one object to another object. For example, we want to attach the customer's purchase order to Sales Order and Billing document once the billing document is generated.

To copy the attachments between the objects, we can use the utility method COPY_LINKED_OBJECTS of the class CL_GOS_SERVICE_TOOLS. We need to tell the method using IT_SERVICE_SELECTION, which service needs to be performed i.e. for the attachment copy, we need to perform the "Attachment Create" service. We also let the method know the the source and target.

Here is the Code snippet which copies the attachments between Customers.

*&---------------------------------------------------------------------*

*& Developed by: Naimesh Patel

*& Purpose     : To Copy the Attachment from One Object to Another

*&---------------------------------------------------------------------*

*

REPORT  ztest_np_copy_gos_att.

*

*

DATA: lt_services TYPE tgos_sels.    " Services table typ

DATA: ls_service TYPE sgos_sels.     " Services structure type

DATA: ls_source TYPE sibflporb,      " Source

      ls_target TYPE sibflporb.      " Target

*

START-OF-SELECTION.

*

* Service needs to be performed

  ls_service-sign   = 'I'.

  ls_service-option = 'EQ'.

  ls_service-low    = 'PCATTA_CREA'.

  APPEND ls_service TO lt_services.

*

* Source

  ls_source-instid = 'CUST1'.

  ls_source-typeid = 'KNA1'.

  ls_source-catid  = 'BO'.

*

* Target

  ls_target-instid = 'CUST2'.

  ls_target-typeid = 'KNA1'.

  ls_target-catid  = 'BO'.

*

* Copy the objects between Source and Target

  cl_gos_service_tools=>copy_linked_objects(

      is_source            = ls_source

      is_target            = ls_target

      it_service_selection = lt_services

         ).

*

  COMMIT WORK.

SALV Table 14 - Editable Checkbox

2010-01-18T13:15:00.002-06:00

Editable Checkbox in the SALV table

In the series of the SALV Model Table display in SAP ABAP, today we will see how to get the editable checkbox in ALV Grid. You can find all the Previous discussion at Tutorials > SALV Table Display.

To get the selectable (editable) checkbox, we need to get the specific column from the column object. After this, we need to set the cell type as IF_SALV_C_CELL_TYPE=>CHECKBOX_HOTSPOT by using the method SET_CELL_TYPE. To update the values in the checkbox, we need to handle the event LINK_CLICK. This event LINK_CLICK is triggered when we click on the hotspot enabled checkbox. In the event handler method, we need to change the value of the checkbox field and call the REFRESH method to refresh the value on the ALV.

Code Snippet

  
*&---------------------------------------------------------------------*
*& SALV Table, editable checkbox
*&
*&---------------------------------------------------------------------*
REPORT  zsalv_editable_checkbox.
*
*----------------------------------------------------------------------*
*       CLASS lcl_report DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_report DEFINITION.
*
  PUBLIC SECTION.
*
*   Final output table
    TYPES: BEGIN OF ty_vbak,
           vbeln TYPE vbak-vbeln,
           erdat TYPE erdat,
           auart TYPE auart,
           kunnr TYPE kunnr,
           check TYPE flag,
           END   OF ty_vbak.
*
    DATA: t_vbak TYPE STANDARD TABLE OF ty_vbak.
*
*   ALV reference
    DATA: o_alv TYPE REF TO cl_salv_table.
*
    METHODS:
*     data selection
      get_data,
*
*     Generating output
      generate_output.
*
*
ENDCLASS.                    "lcl_report DEFINITION
*
CLASS lcl_event_handler DEFINITION.
*
  PUBLIC SECTION.
    METHODS:
      on_link_click FOR EVENT link_click OF cl_salv_events_table
        IMPORTING row column.
*
ENDCLASS.                    "lcl_event_handler DEFINITION
*
*
START-OF-SELECTION.
  DATA: lo_report TYPE REF TO lcl_report.
*
  CREATE OBJECT lo_report.
*
  lo_report->get_data( ).
*
  lo_report->generate_output( ).
*
*----------------------------------------------------------------------*
*       CLASS lcl_report IMPLEMENTATION
*----------------------------------------------------------------------*
CLASS lcl_report IMPLEMENTATION.
*
  METHOD get_data.
*   data selection
    SELECT vbeln erdat auart kunnr
           INTO  TABLE t_vbak
           FROM  vbak
           UP TO 20 ROWS.
*
  ENDMETHOD.                    "get_data
*
*.......................................................................
  METHOD generate_output.
*
* exception class
    DATA: lx_msg TYPE REF TO cx_salv_msg.
    TRY.
        cl_salv_table=>factory(
          IMPORTING
            r_salv_table = o_alv
          CHANGING
            t_table      = t_vbak ).
      CATCH cx_salv_msg INTO lx_msg.
    ENDTRY.
*
*...Get all the Columns
    DATA: lo_cols TYPE REF TO cl_salv_columns.
    lo_cols = o_alv->get_columns( ).
*
*   set the Column optimization
    lo_cols->set_optimize( 'X' ).
*
*...Process individual columns
    DATA: lo_column TYPE REF TO cl_salv_column_list.
*
*   Change the properties of the Columns KUNNR
    TRY.
        lo_column ?= lo_cols->get_column( 'CHECK' ).
        lo_column->set_cell_type( if_salv_c_cell_type=>checkbox_hotspot ).
        lo_column->set_output_length( 10 ).
      CATCH cx_salv_not_found.                          "#EC NO_HANDLER
    ENDTRY.
*
*   Get the event object
    DATA: lo_events TYPE REF TO cl_salv_events_table.
    lo_events = o_alv->get_event( ).
*
*   Instantiate the event handler object
    DATA: lo_event_handler TYPE REF TO lcl_event_handler.
    CREATE OBJECT lo_event_handler.
*
*   event handler
    SET HANDLER lo_event_handler->on_link_click FOR lo_events.
*
*   Displaying the ALV
*   Here we will call the DISPLAY method to get the output on the screen
    o_alv->display( ).
*
  ENDMETHOD.                    "generate_output
*
ENDCLASS.                    "lcl_report IMPLEMENTATION
*
*----------------------------------------------------------------------*
*       CLASS lcl_event_handler IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_event_handler IMPLEMENTATION.
*
  METHOD on_link_click.
*
*   Get the value of the checkbox and set the value accordingly
*   Refersh the table
    FIELD-SYMBOLS: <lfa_data> LIKE LINE OF lo_report->t_vbak.
    READ TABLE lo_report->t_vbak ASSIGNING <lfa_data> INDEX row.
    CHECK sy-subrc IS INITIAL.
    IF <lfa_data>-check IS INITIAL.
      <lfa_data>-check = 'X'.
    ELSE.
      CLEAR <lfa_data>-check.
    ENDIF.
    lo_report->o_alv->refresh( ).
  ENDMETHOD.                    "on_link_click
*
ENDCLASS.                    "lcl_event_handler IMPLEMENTATION

SALV Table 13 - Apply Sorts

2010-01-04T22:00:00.003-06:00

Apply Sorts to SALV Table

In the series of the SALV Model Table display in SAP ABAP, today we will see how to apply Sorting to the ALV Grid. You can find all the Previous discussion at Tutorials > SALV Table Display.

Sorts are very important in the reporting. Sorting also provides us the functionality to have the Subtotal on amount / quantity fields. To achieve the sort functions, we have the class CL_SALV_SORTS.

We need to use the method ADD_SORTS of the class CL_SALV_SORTS to apply a filter on a specific column. We need to pass the column name e.g. AUART in the parameter COLUMNNAME. We can also set the of sort direction by setting up the parameter SEQUENCE.

For this example, I have added a sort on the AUART column and the subtotal for the NETWR column.

Code Snippet

  
REPORT  ztest_oo_alv_sorts.
*
*----------------------------------------------------------------------*
*       CLASS lcl_report DEFINITION
*----------------------------------------------------------------------*
CLASS lcl_report DEFINITION.
*
  PUBLIC SECTION.
*
*   Final output table
    TYPES: BEGIN OF ty_vbak,
           vbeln     TYPE vbak-vbeln,
           erdat     TYPE erdat,
           auart     TYPE auart,
           kunnr     TYPE kunnr,
           netwr     TYPE netwr,
           END   OF ty_vbak.
    TYPES: ty_t_vbak TYPE STANDARD TABLE OF ty_vbak.
*
    DATA: t_vbak TYPE STANDARD TABLE OF ty_vbak.
*
*   ALV reference
    DATA: o_alv TYPE REF TO cl_salv_table.
*
    METHODS:
*     data selection
      get_data,
*
*     Generating output
      generate_output.
*
*$*$*.....CODE_ADD_1 - Begin..................................1..*$*$*
*
*    In this section we will define the private methods which can
*      be implemented to set the properties of the ALV and can be
*      called in the
*
  PRIVATE SECTION.
    METHODS:
      set_pf_status
        CHANGING
          co_alv TYPE REF TO cl_salv_table.
*
    METHODS:
      set_sorts
        CHANGING
          co_alv TYPE REF TO cl_salv_table.
*
    METHODS:
      set_aggregations
        CHANGING
          co_alv  TYPE REF TO cl_salv_table.
*
*$*$*.....CODE_ADD_1 - End....................................1..*$*$*
*
ENDCLASS.                    "lcl_report DEFINITION
*
*
START-OF-SELECTION.
  DATA: lo_report TYPE REF TO lcl_report.
*
  CREATE OBJECT lo_report.
*
  lo_report->get_data( ).
*
  lo_report->generate_output( ).
*
*----------------------------------------------------------------------*
*       CLASS lcl_report IMPLEMENTATION
*----------------------------------------------------------------------*
CLASS lcl_report IMPLEMENTATION.
*
  METHOD get_data.
*   data selection
    SELECT vbeln erdat auart kunnr netwr
           INTO  CORRESPONDING FIELDS OF TABLE t_vbak
           FROM  vbak
           up to 20 ROWS.
*
  ENDMETHOD.                    "get_data
*
*.......................................................................
  METHOD generate_output.
* New ALV instance
*   We are calling the static Factory method which will give back
*   the ALV object reference.
*
* exception class
    DATA: lx_msg TYPE REF TO cx_salv_msg.
    TRY.
        cl_salv_table=>factory(
          IMPORTING
            r_salv_table = o_alv
          CHANGING
            t_table      = t_vbak ).
      CATCH cx_salv_msg INTO lx_msg.
    ENDTRY.
*
*$*$*.....CODE_ADD_2 - Begin..................................2..*$*$*
*
*    In this area we will call the methods which will set the
*      different properties to the ALV
*
*   Set default PF status
    CALL METHOD set_pf_status
      CHANGING
        co_alv = o_alv.
*
*   Set SORT
    CALL METHOD set_sorts
      CHANGING
        co_alv = o_alv.
*
*   Set the Aggregations
    CALL METHOD set_aggregations
      CHANGING
        co_alv = o_alv.
*$*$*.....CODE_ADD_2 - End....................................2..*$*$*
*
*
* Displaying the ALV
*   Here we will call the DISPLAY method to get the output on the screen
    o_alv->display( ).
*
  ENDMETHOD.                    "generate_output
*
*$*$*.....CODE_ADD_3 - Begin..................................3..*$*$*
*
*    In this area we will implement the methods which are defined in
*      the class definition
*
*
  METHOD set_pf_status.
*
    DATA: lo_functions TYPE REF TO cl_salv_functions_list.
*
    lo_functions = co_alv->get_functions( ).
    lo_functions->set_default( abap_true ).
*
  ENDMETHOD.                    "set_pf_status
*
  METHOD set_sorts.
*
    DATA: lo_sort TYPE REF TO cl_salv_sorts.
*
*   get Sort object
    lo_sort = co_alv->get_sorts( ).
*
*   Set the SORT on the AUART with Subtotal
    TRY.
        CALL METHOD lo_sort->add_sort
          EXPORTING
            columnname = 'AUART'
            subtotal   = if_salv_c_bool_sap=>true.
      CATCH cx_salv_not_found .                         "#EC NO_HANDLER
      CATCH cx_salv_existing .                          "#EC NO_HANDLER
      CATCH cx_salv_data_error .                        "#EC NO_HANDLER
    ENDTRY.
*
  ENDMETHOD.                    "set_sorts
*
  METHOD set_aggregations.
*
    DATA: lo_aggrs TYPE REF TO cl_salv_aggregations.
*
    lo_aggrs = co_alv->get_aggregations( ).
*
*   Add TOTAL for COLUMN NETWR
    TRY.
        CALL METHOD lo_aggrs->add_aggregation
          EXPORTING
            columnname  = 'NETWR'
            aggregation = if_salv_c_aggregation=>total.
      CATCH cx_salv_data_error .                        "#EC NO_HANDLER
      CATCH cx_salv_not_found .                         "#EC NO_HANDLER
      CATCH cx_salv_existing .                          "#EC NO_HANDLER
    ENDTRY.
*
  ENDMETHOD.                    "set_aggregations
*
*
*
*$*$*.....CODE_ADD_3 - End....................................3..*$*$*
ENDCLASS.                    "lcl_report IMPLEMENTATION

SAP Help on SALV Column Sorting:
ALV Object Model - Sorting by Columns

SALV OM Undocumented Limitations - Initial Lines in Details Screen

2009-12-30T20:28:00.003-06:00

SALV Limitations: Initial Lines in Detail screen

This is another undocumented limitation of the SALV OM: Initial Lines and Detail Screen Title is not possible in ALV (created using container) with SALV OM. These features are possible in the ALV Grid created with the CL_GUI_ALV_GRID.

In the Layout TYPE LVC_S_LAYO, we have the provision to set the Initial lines in the detail view by setting up the field DETAILINIT. We can set the title to detail screen as well by populating the value in the field DETAILTITL. These features are not available in the SALV OM. Method GET_LVC_LAYOUT of Class CL_SALV_CONTROLLER_METADATA sets the Layout to TYPE LVC_S_LAYO for the ALV GRID. In fact SALV OM only sets few fields of Layout in this method. It only populated very few fields of the LVC_S_LAYO.

Discussion in SCN forum: Detail initial lines for SALV

SALV OM Undocumented Limitations - Separator in the Toolbar

2009-12-29T18:44:00.004-06:00

SALV Limitations: Separator in Toolbar

In this new series on SALV Object Model (SALV OM), I will document some of the Limitations which are not documented in standard SAP documentation.

In the ALV GRID (created using container) type of SALV, we can't have a Separator in the Toolbar. To add the separator in the Toolbar, button type (BUTN_TYPE) field of toolbar must be set to "3". SALV OM doesn't allow to specify this button type. It assumes that there would be only normal buttons (BUTN_TYPE = '0'). Method IF_SALV_TOOLBAR_ADAPTER~BUILD_UIFUNCTION in class CL_SALV_GRID_ADAPTER, creates the toolbar functions.

Code Lines which impose this restriction in SALV OM

To overcome this limitation, SAP could enhance SALV OM to provide us the method to set the button type in the CL_SALV_FUNCTION and use that button type here in the code instead of assuming that button as the normal button.

SALV Table 12 - Apply Filters

2009-12-28T22:26:00.002-06:00

Apply Filters to SALV Table

In the series of the SALV Model Table display in SAP ABAP, today we will see how to apply Filters to the ALV Grid. You can find all the Previous discussion at Tutorials > SALV Table Display.

Filters are important to display only values required by the users. i.e. See only the "Red" Lights from the Traffic Light report. To achieve this functionality, we have the CL_SALV_FILTERS class of SAP OM.

We can use the method ADD_FILTERS of the class CL_SALV_FILTERS to apply the filter on a specific column. The values in the filters would work exactly like values in a Range or Select-options i.e. SIGN, OPTION, LOW & HIGH. For this example, I have applied filters on the ERDAT column to only show records with a specific date.

Code Snippet to Apply Filters

  
REPORT  ztest_oo_alv_filters.
*
*----------------------------------------------------------------------*
*       Code to Apply Filters to SALV Table Display
*----------------------------------------------------------------------*
*       CLASS lcl_report DEFINITION
*----------------------------------------------------------------------*
CLASS lcl_report DEFINITION.
*
  PUBLIC SECTION.
*
*   Final output table
    TYPES: BEGIN OF ty_vbak,
           vbeln     TYPE vbak-vbeln,
           erdat     TYPE erdat,
           auart     TYPE auart,
           kunnr     TYPE kunnr,
           netwr     TYPE netwr,
           END   OF ty_vbak.
    TYPES: ty_t_vbak TYPE STANDARD TABLE OF ty_vbak.
*
    DATA: t_vbak TYPE STANDARD TABLE OF ty_vbak.
*
*   ALV reference
    DATA: o_alv TYPE REF TO cl_salv_table.
*
    METHODS:
*     data selection
      get_data,
*
*     Generating output
      generate_output.
*
*$*$*.....CODE_ADD_1 - Begin..................................1..*$*$*
*
*    In this section we will define the private methods which can
*      be implemented to set the properties of the ALV and can be
*      called in the
*
  PRIVATE SECTION.
    METHODS:
      set_pf_status
        CHANGING
          co_alv TYPE REF TO cl_salv_table.
*
    METHODS:
      set_filters
        CHANGING
          co_alv TYPE REF TO cl_salv_table.
*
*$*$*.....CODE_ADD_1 - End....................................1..*$*$*
*
ENDCLASS.                    "lcl_report DEFINITION
*
*
START-OF-SELECTION.
  DATA: lo_report TYPE REF TO lcl_report.
*
  CREATE OBJECT lo_report.
*
  lo_report->get_data( ).
*
  lo_report->generate_output( ).
*
*----------------------------------------------------------------------*
*       CLASS lcl_report IMPLEMENTATION
*----------------------------------------------------------------------*
CLASS lcl_report IMPLEMENTATION.
*
  METHOD get_data.
*   data selection
    SELECT vbeln erdat auart kunnr netwr
           INTO  CORRESPONDING FIELDS OF TABLE t_vbak
           FROM  vbak
           where erdat ge '20090101'.
*
  ENDMETHOD.                    "get_data
*
*.......................................................................
  METHOD generate_output.
* New ALV instance
*   We are calling the static Factory method which will give back
*   the ALV object reference.
*
* exception class
    DATA: lx_msg TYPE REF TO cx_salv_msg.
    TRY.
        cl_salv_table=>factory(
          IMPORTING
            r_salv_table = o_alv
          CHANGING
            t_table      = t_vbak ).
      CATCH cx_salv_msg INTO lx_msg.
    ENDTRY.
*
*$*$*.....CODE_ADD_2 - Begin..................................2..*$*$*
*
*    In this area we will call the methods which will set the
*      different properties to the ALV
*
*   Set default PF status
    CALL METHOD set_pf_status
      CHANGING
        co_alv = o_alv.
*
*   Set Filters
    CALL METHOD set_filters
      CHANGING
        co_alv = o_alv.
*$*$*.....CODE_ADD_2 - End....................................2..*$*$*
*
*
* Displaying the ALV
*   Here we will call the DISPLAY method to get the output on the screen
    o_alv->display( ).
*
  ENDMETHOD.                    "generate_output
*
*$*$*.....CODE_ADD_3 - Begin..................................3..*$*$*
*
*    In this area we will implement the methods which are defined in
*      the class definition
*
*
  METHOD set_pf_status.
*
    DATA: lo_functions TYPE REF TO cl_salv_functions_list.
*
    lo_functions = co_alv->get_functions( ).
    lo_functions->set_default( abap_true ).
*
  ENDMETHOD.                    "set_pf_status
*
  METHOD set_filters.
*
    DATA: lo_filters TYPE REF TO cl_salv_filters.
*
    lo_filters = co_alv->get_filters( ).
*
*   Set the filter for the column ERDAT
*     the filter criteria works exactly same as any
*     RANGE or SELECT-OPTIONS works.
    TRY.
        CALL METHOD lo_filters->add_filter
          EXPORTING
            columnname = 'ERDAT'
            sign       = 'I'
            option     = 'EQ'
            low        = '20091214'
*           high       =
            .
      CATCH cx_salv_not_found .                         "#EC NO_HANDLER
      CATCH cx_salv_data_error .                        "#EC NO_HANDLER
      CATCH cx_salv_existing .                          "#EC NO_HANDLER
    ENDTRY.
*
*
  ENDMETHOD.                    "set_filters
*
*
*
*$*$*.....CODE_ADD_3 - End....................................3..*$*$*
ENDCLASS.                    "lcl_report IMPLEMENTATION

SALV Table 11 - Apply Aggregations

2009-12-22T18:00:00.004-06:00

Apply Aggregations like Totals, Minimum values to SALV Table

In the series of the SALV Model Table display in SAP ABAP, today we will see how to apply aggregations to the ALV Grid. You can find all the Previous discussion at Tutorials > SALV Table Display.

Aggregations plays important role in the reporting. E.g. Providing the TOTALS, Minimum values, Maximum values, Subtotals etc. To achieve this in the SALV model, we have the class CL_SALV_AGGREGATIONS.

For instance, to apply TOTALS on the the NETWR column (as shown in the example) we need to use the method ADD_AGGREGATION on this column. The parameter AGGREGATION would be used to determine the type of the aggregation. Interface IF_SALV_C_AGGREGATION contains the constants which can be used in this parameter.

In this example I need to change the output table to add column NETWR as compared to previous discussion in this series, so I will provide the entire code which generate the output which has all three scenario. For test purpose, We will apply TOTALS on the NETWR column. Once the TOTAL is applied, we will bring the TOTAL row at the top.

Code Snippet to Apply Aggregations

  
REPORT  ztest_oo_alv_aggr.
*
*----------------------------------------------------------------------*
*       Code to apply Aggregations to SALV Table display
*----------------------------------------------------------------------*
*       CLASS lcl_report DEFINITION
*----------------------------------------------------------------------*
CLASS lcl_report DEFINITION.
*
  PUBLIC SECTION.
*
*   Final output table
    TYPES: BEGIN OF ty_vbak,
           vbeln     TYPE vbak-vbeln,
           erdat     TYPE erdat,
           auart     TYPE auart,
           kunnr     TYPE kunnr,
           netwr     TYPE netwr,
           END   OF ty_vbak.
    TYPES: ty_t_vbak TYPE STANDARD TABLE OF ty_vbak.
*
    DATA: t_vbak TYPE STANDARD TABLE OF ty_vbak.
*
*   ALV reference
    DATA: o_alv TYPE REF TO cl_salv_table.
*
    METHODS:
*     data selection
      get_data,
*
*     Generating output
      generate_output.
*
*$*$*.....CODE_ADD_1 - Begin..................................1..*$*$*
*
*    In this section we will define the private methods which can
*      be implemented to set the properties of the ALV and can be
*      called in the
*
  PRIVATE SECTION.
    METHODS:
      set_pf_status
        CHANGING
          co_alv TYPE REF TO cl_salv_table.
*
    METHODS:
      set_aggregations
        CHANGING
          co_alv  TYPE REF TO cl_salv_table.
*
*$*$*.....CODE_ADD_1 - End....................................1..*$*$*
*
ENDCLASS.                    "lcl_report DEFINITION
*
*
START-OF-SELECTION.
  DATA: lo_report TYPE REF TO lcl_report.
*
  CREATE OBJECT lo_report.
*
  lo_report->get_data( ).
*
  lo_report->generate_output( ).
*
*----------------------------------------------------------------------*
*       CLASS lcl_report IMPLEMENTATION
*----------------------------------------------------------------------*
CLASS lcl_report IMPLEMENTATION.
*
  METHOD get_data.
*   data selection
    SELECT vbeln erdat auart kunnr netwr
           INTO  CORRESPONDING FIELDS OF TABLE t_vbak
           FROM  vbak
           UP TO 20 ROWS.
*
  ENDMETHOD.                    "get_data
*
*.......................................................................
  METHOD generate_output.
* New ALV instance
*   We are calling the static Factory method which will give back
*   the ALV object reference.
*
* exception class
    DATA: lx_msg TYPE REF TO cx_salv_msg.
    TRY.
        cl_salv_table=>factory(
          IMPORTING
            r_salv_table = o_alv
          CHANGING
            t_table      = t_vbak ).
      CATCH cx_salv_msg INTO lx_msg.
    ENDTRY.
*
*$*$*.....CODE_ADD_2 - Begin..................................2..*$*$*
*
*    In this area we will call the methods which will set the
*      different properties to the ALV
*
*   Set default PF status
    CALL METHOD set_pf_status
      CHANGING
        co_alv = o_alv.
*
*   Set the colors to ALV display
    CALL METHOD set_aggregations
      CHANGING
        co_alv = o_alv.
*$*$*.....CODE_ADD_2 - End....................................2..*$*$*
*
*
* Displaying the ALV
*   Here we will call the DISPLAY method to get the output on the screen
    o_alv->display( ).
*
  ENDMETHOD.                    "generate_output
*
*$*$*.....CODE_ADD_3 - Begin..................................3..*$*$*
*
*    In this area we will implement the methods which are defined in
*      the class definition
*
*
  METHOD set_pf_status.
*
    DATA: lo_functions TYPE REF TO cl_salv_functions_list.
*
    lo_functions = co_alv->get_functions( ).
    lo_functions->set_default( abap_true ).
*
  ENDMETHOD.                    "set_pf_status
*
  METHOD set_aggregations.
*
    DATA: lo_aggrs TYPE REF TO cl_salv_aggregations.
*
    lo_aggrs = co_alv->get_aggregations( ).
*
*   Add TOTAL for COLUMN NETWR
    TRY.
        CALL METHOD lo_aggrs->add_aggregation
          EXPORTING
            columnname  = 'NETWR'
            aggregation = if_salv_c_aggregation=>total.
      CATCH cx_salv_data_error .                        "#EC NO_HANDLER
      CATCH cx_salv_not_found .                         "#EC NO_HANDLER
      CATCH cx_salv_existing .                          "#EC NO_HANDLER
    ENDTRY.
*
*   Bring the total line to top
    lo_aggrs->set_aggregation_before_items( ).
*
  ENDMETHOD.                    "set_aggregations
*
*
*
*$*$*.....CODE_ADD_3 - End....................................3..*$*$*
ENDCLASS.                    "lcl_report IMPLEMENTATION

Object Oriented Design Principles (OODP): Open-Closed Principle(OCP)

2009-12-20T09:37:00.003-06:00

Open-Closed Principle (OCP)

This is one of my published blogs on SCN - SAP Community Network.

Definition:
The name itself sounds like contradicting – OPEN & CLOSE, but by definition, A module should be OPEN for extension but CLOSED for modification. The Open-Closed Principle (OCP) is one of the most important Design Principle. OCP originated from the work of by the Bertrand Meyer.

In simple words: We can add new features in the module without changing the existing code (CLOSED) but by adding new code (OPEN). By following this principle, we can make sure that by changing the code in the method we are not going to break existing functionality. Let us try to see it using the example.

Continue reading here:
Object Oriented Design Principles (OODP): Open-Closed Principle(OCP)

Measure the Performance between Break-Points using SE30

2009-12-16T18:02:00.011-06:00

Using transaction SE30 measure the Performance between breakpoints

We can measure the runtime and check the performance of the program by using the transaction SE30. SAP Help on the Runtime Analysis using SE30.

Today we will elaborate the option to measure the performance of the specific part of the code using the SE30. This option would be helpful when we want to measure the performance of particular subroutine, FM, Select query etc. We have the option to start the runtime analysis and stop it on the fly by options System > Utilities > Runtime Analysis > Switch On and Switch Off.

For demo, we will set two breakpoints: one before starting the FM and one after FM.

When we reach at the breakpoint and we try to start the performance measurement by option Utilities > Runtime Analysis > Switch On, system would give the message as "The Particular units" option is not selected.

This message appears because the DEFAULT variant doesn't have this option selected. You can see this variant in SE30. Enter the DEFAULT and press the "Display" button.

So, we need to select the option "Particular Units" in the measurement variant. To do this, we will copy this standard measurement variant to user specific variant and then select the option "Particular Units".

To measure the performance:
1) Run SE30
2) Select this newly copied variant. Here we need to select User Defined variant.

3) Enter the required program / transaction and measure it
4) When it reaches to the breakpoint ON the measurement by System > Utilities > Runtime Analysis > Switch On
5) Press F8
6) When it reaches to the next breakpoint ON the measurement by System > Utilities > Runtime Analysis > Switch Off
7) After finishing the entire transaction, press the evaluate button to evaluate the performance of required code lines.

TIP:
Runtime performance can be switched ON by enter /RON in the transaction box when it reaches to the desired breakpoint. Same way /ROFF could be used to switch off the performance measurement.

Use of Field-symbols vs Work area

2009-12-15T17:54:00.005-06:00

To use the Field-symbols against the Work Area for Internal table processing

Internal table processing is essential part of any ABAP program. Generally, we use the explicit work area to process the internal table like appending & modifying records. We can reduce the time and improve the performance of the program by using the field-symbols.

When we use the LOOP construct with the explicit work area, system need to engage the resources to put the required record in the work area, process it and move it back to the table if the needed. This additional processing time could be saved by using the field-symbol. By using the field-symbols we can save this additional time and improve the performance. Field-symbols are similar to dereferenced pointers in C. While using the field-symbol, system uses the same memory allocated to that particular field in the record instead of moving it to work area and processing. More on field-symbols can be found at: Field-Symbols on SAP Help.

This code snippet shows how to use the field-symbols to process the loop with time measurement.

Code Snippet

  
*&---------------------------------------------------------------------*
*&  Illustrate the performance gain by using the field-symbols
*&  over header areas
*&---------------------------------------------------------------------*
*
REPORT  ztest_np_loop_fs.
*
DATA: i_bseg TYPE STANDARD TABLE OF bseg,
      wa_bseg LIKE LINE OF i_bseg.
*
DATA: lv_flag TYPE flag,
      lv_sta_time TYPE timestampl,
      lv_end_time TYPE timestampl,
      lv_diff_w   TYPE p DECIMALS 5,
      lv_diff_f   LIKE lv_diff_w,
      lv_save     LIKE lv_diff_w.
*
FIELD-SYMBOLS: <fs_bseg> LIKE LINE OF i_bseg.
*
* data selection = 10,000 records
SELECT * FROM bseg INTO TABLE i_bseg UP TO 100 ROWS.
*
* Begin - Processing with Work area
GET TIME STAMP FIELD lv_sta_time.
LOOP AT i_bseg INTO wa_bseg.
  IF lv_flag = 'X'.
    wa_bseg-sgtxt = 'TEST'.
    MODIFY i_bseg FROM wa_bseg.
  ENDIF.
  CLEAR wa_bseg.
  IF lv_flag IS INITIAL.
    lv_flag = 'X'.
  ENDIF.
ENDLOOP.
GET TIME STAMP FIELD lv_end_time.
lv_diff_w = lv_end_time - lv_sta_time.
WRITE: /(15) 'Work area', lv_diff_w.
* End   - Processing with Work Area
*
CLEAR: lv_flag,
       lv_sta_time,
       lv_end_time.
* Begin - Processing with Field-Symbols
GET TIME STAMP FIELD lv_sta_time.
LOOP AT i_bseg ASSIGNING <fs_bseg>.
  IF lv_flag = 'X'.
    <fs_bseg>-sgtxt = 'TEST'.
  ENDIF.
  IF lv_flag IS INITIAL.
    lv_flag = 'X'.
  ENDIF.
ENDLOOP.
GET TIME STAMP FIELD lv_end_time.
lv_diff_f = lv_end_time - lv_sta_time.
WRITE: /(15) 'Field-Symbol', lv_diff_f.
* End   - Processing with Work Area
*
* Net time saving
lv_save = lv_diff_w - lv_diff_f.
WRITE: /(15) 'Total Save', lv_save.
WRITE: / 'Done'.

Some statistics:
In this performance measurement, time taken by the work area to process is considered as the 100%. By using the field-symbols, we can definitely improve the performance.

Parallel Cursor - 2: without using READ

2009-12-14T19:29:00.003-06:00

Parallel Cursor without using READ

In previous post Parallel Cursor - To speed up performance of Nested LOOP, we have seen a technique how to speed up the performance of the nested LOOP constructs in ABAP. In today's post, we will see another variance of the Parallel cursor technique. In this technique, we will exit out the inner LOOP when both keys are not matching by saving the LOOP index in a variable. This index variable would be used in the LOOP construct to start the LOOP. Initially, this index variable would be set to 1. Statistics shows that this new technique is powerful over the technique as shown in the previous post which uses the READ TABLE.

Here is the code snippet to achieve this Parallel Cursor technique:

Code Snippet

  
*&---------------------------------------------------------------------*
*& Report  ZTEST_NP_PARALLEL_CURSOR
*& Purpose: Illustration on how to use Parallel Cursor
*&---------------------------------------------------------------------*
*
REPORT  ztest_np_parallel_cursor.
*
TYPES: ty_t_vbak TYPE STANDARD TABLE OF vbak.
DATA: it_vbak TYPE ty_t_vbak .
*
TYPES: ty_t_vbap TYPE STANDARD TABLE OF vbap.
DATA: it_vbap TYPE ty_t_vbap.
*
FIELD-SYMBOLS: <lfs_vbak> LIKE LINE OF it_vbak,
               <lfs_vbap> LIKE LINE OF it_vbap.
*
* necessary data selection
SELECT * FROM vbak
  INTO TABLE it_vbak
  UP TO 100 ROWS.
CHECK it_vbak IS NOT INITIAL.
SELECT * FROM vbap
  INTO TABLE it_vbap
  FOR ALL ENTRIES IN it_vbak
  WHERE vbeln = it_vbak-vbeln.
*
DATA: lv_start_time TYPE timestampl,
      lv_end_time   TYPE timestampl,
      lv_diff       TYPE timestampl.
DATA: lv_tabix TYPE i.
*
*....... Parallel Cursor with Nested Loop .......................
* Get the Start Time
GET TIME STAMP FIELD lv_start_time.
*
* Starting the Parallel Cursor
SORT: it_vbak BY vbeln,
      it_vbap BY vbeln.
LOOP AT it_vbak ASSIGNING <lfs_vbak>.
*
* Read the second internal table with BINARY SEARCH
  READ TABLE it_vbap TRANSPORTING NO FIELDS
       WITH KEY vbeln = <lfs_vbak>-vbeln
       BINARY SEARCH.
* Get the TABIX number
  lv_tabix = sy-tabix.
* Start the LOOP from the first accessed record in
* previous READ i.e. LV_TABIX
  LOOP AT it_vbap FROM lv_tabix ASSIGNING <lfs_vbap> .
*
*   End the LOOP, when there is no more record with similar key
    IF <lfs_vbap>-vbeln <> <lfs_vbak>-vbeln.
      EXIT.
    ENDIF.
*   Rest of the logic would go from here...
*
  ENDLOOP.
*
ENDLOOP.
*
* Get the end time
GET TIME STAMP FIELD lv_end_time.
*
* Actual time Spent:
lv_diff = lv_end_time - lv_start_time.
WRITE: /(50) 'Time Spent on Parallel Cursor Nested loops:', lv_diff.
CLEAR: lv_start_time, lv_end_time, lv_diff.
*
*....... Parallel Cursor - 2 with Nested Loop ...................
Clear lv_tabix.
* Get the Start Time
GET TIME STAMP FIELD lv_start_time.
*
* Starting the Parallel Cursor
SORT: it_vbak BY vbeln,
      it_vbap BY vbeln.
lv_tabix = 1.     " Set the starting index 1
LOOP AT it_vbak ASSIGNING <lfs_vbak>.
*
* Start the nested LOOP from the index
  LOOP AT it_vbap from lv_tabix
                  ASSIGNING <lfs_vbap>.
*   Save index & Exit the loop, if the keys are not same
    if <lfs_vbak>-vbeln <> <lfs_vbap>-vbeln.
      lv_tabix = sy-tabix.
      EXIT.
    ENDIF.
*   Rest of the logic would go from here...
*
  ENDLOOP.
ENDLOOP.
*
* Get the end time
GET TIME STAMP FIELD lv_end_time.
*
* Actual time Spent:
lv_diff = lv_end_time - lv_start_time.
WRITE: /(50) 'Time Spent on Parallel Cursor 2 Nested loops', lv_diff.
CLEAR: lv_start_time, lv_end_time, lv_diff.

This statistics and graph shows the time used by the nested LOOP as the 100%. For the 1000 VBAK records, parallel cursor technique with READ consumes 1.84% time compare to nested LOOPs 100%. This technique without READ TABLE only requires 1.05% time compare to 100% of nested LOOPs.

Parallel Cursor - To speed up performance of Nested LOOP

2009-12-13T16:59:00.005-06:00

Technique to speed up the performance of the Nested LOOP - Parllel Cursor

I'm back after a long break. Today, we will tackle down the biggest performance related issue around the Nested Loops.

Traditionally in ABAP, we use the LOOP using the WHERE clause for Nested loops. This type of nested loops are very common in our day-to-day programming. But, the cost, in terms of performance, is higher when we use the nested loops. This cost would become a key issue when working with huge tables e.g. BKPF & BSEG, VBAK & VBAP, MKPF & MSEG. Sometimes, this cost increases and reaches to the point where program fails to finish the execution.

We have the concept of Parallel Cursor exists in ABAP to overcome this hurdle and reduce this cost. In parallel cursor, we first try to see if there is any entry exist in the second table inside the LOOP construct of first table. We use the READ .. WITH KEY .. BINARY SEARCH to check if the entry exist in the second table. We use this record number SY-TABIX to LOOP on the second table using LOOP .. FROM index.

This code snippet gives us the idea of the time taken by both the nested loops and the parallel cursor loops.

Code Snippet

  
*&---------------------------------------------------------------------*
*& Report  ZTEST_NP_PARALLEL_CURSOR
*& Purpose: Illustration on how to use Parallel Cursor
*&---------------------------------------------------------------------*
*
REPORT  ztest_np_parallel_cursor.
*
TYPES: ty_t_vbak TYPE STANDARD TABLE OF vbak.
DATA: it_vbak TYPE ty_t_vbak .
*
TYPES: ty_t_vbap TYPE STANDARD TABLE OF vbap.
DATA: it_vbap TYPE ty_t_vbap.
*
FIELD-SYMBOLS: <lfs_vbak> LIKE LINE OF it_vbak,
               <lfs_vbap> LIKE LINE OF it_vbap.
*
* necessary data selection
SELECT * FROM vbak
  INTO TABLE it_vbak
  UP TO 1000 ROWS.
CHECK it_vbak IS NOT INITIAL.
SELECT * FROM vbap
  INTO TABLE it_vbap
  FOR ALL ENTRIES IN it_vbak
  WHERE vbeln = it_vbak-vbeln.
*
DATA: lv_start_time TYPE timestampl,
      lv_end_time   TYPE timestampl,
      lv_diff       TYPE timestampl.
DATA: lv_tabix TYPE i.
*
*...... Normal Nested Loop .................................
* Get the Start Time
GET TIME STAMP FIELD lv_start_time.
*
* Nested Loop
LOOP AT it_vbak ASSIGNING <lfs_vbak>.
  LOOP AT it_vbap ASSIGNING <lfs_vbap>
                  WHERE vbeln = <lfs_vbak>-vbeln.
  ENDLOOP.
ENDLOOP.
*
* Get the end time
GET TIME STAMP FIELD lv_end_time.
*
* Actual time Spent:
lv_diff = lv_end_time - lv_start_time.
WRITE: /(50) 'Time Spent on Nested Loop', lv_diff.
*
CLEAR: lv_start_time, lv_end_time, lv_diff.
*
*....... Parallel Cursor with Nested Loop .......................
* Get the Start Time
GET TIME STAMP FIELD lv_start_time.
*
* Starting the Parallel Cursor
SORT: it_vbak BY vbeln,
      it_vbap BY vbeln.
LOOP AT it_vbak ASSIGNING <lfs_vbak>.
*
* Read the second internal table with BINARY SEARCH
  READ TABLE it_vbap TRANSPORTING NO FIELDS
       WITH KEY vbeln = <lfs_vbak>-vbeln
       BINARY SEARCH.
* Get the TABIX number
  lv_tabix = sy-tabix.
* Start the LOOP from the first accessed record in
* previous READ i.e. LV_TABIX
  LOOP AT it_vbap FROM lv_tabix ASSIGNING <lfs_vbap> .
*
*   End the LOOP, when there is no more record with similar key
    IF <lfs_vbap>-vbeln <> <lfs_vbak>-vbeln.
      EXIT.
    ENDIF.
*   Rest of the logic would go from here...
*
  ENDLOOP.
*
ENDLOOP.
*
* Get the end time
GET TIME STAMP FIELD lv_end_time.
*
* Actual time Spent:
lv_diff = lv_end_time - lv_start_time.
WRITE: /(50) 'Time Specnt on Parallel Cursor Nested loops:', lv_diff.

I ran this program multiple times and capture this statistics.

Dynamic Parameter Texts in Selection Screen - 2

2009-08-10T19:33:00.009-05:00

Selection Screen Parameter Text by coding using Function Modules

In the last post Dynamic Parameter Texts in Selection Screen (which was so many weeks ago), we discussed how we can change the selection screen parameter by changing the values of some selection screen specific variables. Greets Enno suggested to use the FM SELECTION_TEXTS_MODIFY to handle the selection screen parameters more easily and in standard way.

Some of the readers also left comment on the previous post about the use of this trick. One scenario I came in my mind: Certain Parameter Texts based on the Radio button selection. E.g. We have some radio buttons like Sales Order, Credit Memo, Debit Memo and so on. Based on this radiobutton selection, we want to display the Date's parameter text.

This code snippet will realize this scenario using the FM SELECTION_TEXTS_MODIFY.

Code Snippet to show dynamic parameter text


*&---------------------------------------------------------------------*
*& Report  ZTEST_NP_HELPER
*&
*&---------------------------------------------------------------------*

REPORT  ztest_np_helper.

*----------------------------------------------------------------------*
* Selection Screen Class definition
*----------------------------------------------------------------------*
CLASS lcl_selscr DEFINITION.

  PUBLIC SECTION.
    CLASS-DATA:
      f_date_text TYPE char30.

    CLASS-METHODS:
      set_text
        IMPORTING
          if_name TYPE char8
          if_type TYPE char1
          if_text TYPE char30,

      change_screen.

  PRIVATE SECTION.
    CLASS-DATA:
      t_text TYPE STANDARD TABLE OF rsseltexts.

ENDCLASS.                    "lcl_selscr DEFINITION

*.... Selection Screen
SELECTION-SCREEN: BEGIN OF BLOCK blk1 WITH FRAME TITLE aaa.
PARAMETERS: p_so   RADIOBUTTON GROUP rd1 DEFAULT 'X' USER-COMMAND usr1,
            p_cre  RADIOBUTTON GROUP rd1,
            p_deb  RADIOBUTTON GROUP rd1.
PARAMETERS: p_date TYPE datum.
SELECTION-SCREEN: END OF BLOCK blk1.

*.... Initialization
INITIALIZATION.
  aaa = 'Select an option to continue'.

*.... At Selection-Screen Output
AT SELECTION-SCREEN OUTPUT.
* text for Radiobuttons
  lcl_selscr=>set_text( if_name = 'P_SO'
                        if_type = 'P' if_text = 'Sales Order' ).
  lcl_selscr=>set_text( if_name = 'P_CRE'
                        if_type = 'P' if_text = 'Credit memo' ).
  lcl_selscr=>set_text( if_name = 'P_DEB'
                        if_type = 'P' if_text = 'Debit memo' ).

* determine the text for the P_DATE
  CASE 'X'.
    WHEN p_so.    lcl_selscr=>f_date_text = 'Sales Order Entry Date'.
    WHEN p_cre.   lcl_selscr=>f_date_text = 'Credit Memo Entry Date'.
    WHEN p_deb.   lcl_selscr=>f_date_text = 'Debit Memo Entry Date'.
  ENDCASE.
  lcl_selscr=>set_text( if_name = 'P_DATE'
                        if_type = 'P'
                        if_text = lcl_selscr=>f_date_text ).

* Change the Selection Screen
  lcl_selscr=>change_screen( ).

*.... Start of selection
START-OF-SELECTION.
  WRITE: 'Date Text', lcl_selscr=>f_date_text.

*----------------------------------------------------------------------*
* Selection Screen Class definition
*----------------------------------------------------------------------*
CLASS lcl_selscr IMPLEMENTATION.

  METHOD set_text.
    DATA: la_text LIKE LINE OF t_text.

    la_text-name = if_name.
    la_text-kind = if_type.
    la_text-text = if_text.
    APPEND la_text TO t_text.

  ENDMETHOD.                    "set_text

  METHOD change_screen.
    CALL FUNCTION 'SELECTION_TEXTS_MODIFY'
      EXPORTING
        program  = sy-cprog
      TABLES
        seltexts = t_text.
  ENDMETHOD.                    "change_screen

ENDCLASS.                    "lcl_selscr IMPLEMENTATION

Dynamic Parameter Texts in Selection Screen

2009-04-27T17:29:00.006-05:00

Selection Screen Parameter Text by coding

Sometimes, we need to dispaly the Dynamic Parameter Text for the parameters in the selection screen.

We can use %_parameter_%_APP_%-TEXT to have the parameter text from the coding.

Code Snippet to show dynamic parameter text

  
*---------------------------------------------------------------------
* Shows how to give the selection screen parameter name by
*  using coding
*---------------------------------------------------------------------
REPORT  ZTEST_NP_TMP.
*
DATA: w_carrid TYPE sflight-carrid.
*
** Selection Screen
SELECTION-SCREEN: BEGIN OF BLOCK blk1 WITH FRAME TITLE aaa.
SELECT-OPTIONS:   s_carrid FOR w_carrid.
SELECTION-SCREEN: END   OF BLOCK blk1.
*
INITIALIZATION.
* Description for the parameter
  if sy-uname = 'TEST'.
    %_s_carrid_%_app_%-text = 'Carrier ID'.
  else.
    %_s_carrid_%_app_%-text = 'Flight ID'.
  endif.

Without the code, we would see the selection screen like this:

And with the code, selection screen would be like this:

We can use this trik:
* Dyanmic Parameter text
* While Sharing the example code

Persistent Object Service - Example

2009-04-22T16:55:00.003-05:00

Shows how to use the Persistent object in the Application.

Previously, we have seen Persistent Object Services - Basics. Today we will see how to use the Persistent Object services in the test application. You can find all these under ABAP Objects.

To use the persistent objects, we need to:
Get the Agent Object by accessing the public attribute AGENT in the agent class.
For Read access, get the persistent object by using the GET_PERSISTENT method of the agent object. To create entry using the persistent objects, we need to use the CREATE_PERSISTENT method of the agent object.

Lets see it by example. For demo purpose, we will use the class CL_SPFLI_PERSISTENT.

Code Snippet to show the use of the Persistent Object

  
*&---------------------------------------------------------------------*
*& Shows how to use the Persistent Service to work with Persistent
*&  objects to get data and create entries.
*&---------------------------------------------------------------------*
*
REPORT  ztest_persistent.
*
DATA: lo_spfli_a  TYPE REF TO ca_spfli_persistent,   " Actor Class
      lo_spfli_c  TYPE REF TO cl_spfli_persistent,   " Persistent Class
      lo_exc      TYPE REF TO cx_root.               " Exception
*
DATA: la_cityfrom TYPE spfli-cityfrom.
*
START-OF-SELECTION.
*
* Get the Agent
  lo_spfli_a = ca_spfli_persistent=>agent.
*
***** Reading the Entry
  TRY.
*     Get the Persistent object for key
      lo_spfli_c = lo_spfli_a->get_persistent(
                      i_carrid = 'AA'
                      i_connid = '0017' ).
*
*     Print the CITYFORM, if the persistent object is created
      IF lo_spfli_c IS BOUND.
        la_cityfrom = lo_spfli_c->get_cityfrom( ).
        WRITE: 'City From:', la_cityfrom.
*
*     Write: No data message
      ELSE.
        WRITE: 'No data found'.
      ENDIF.
*
*   Exception handling
    CATCH cx_root INTO lo_exc.
      MESSAGE lo_exc TYPE 'S'.
  ENDTRY.
  CLEAR: lo_spfli_a,
         lo_spfli_c.
*
***** Creating the Entry
* Get the Agent (same agent object due to Singleton)
  lo_spfli_a = ca_spfli_persistent=>agent.
*
  TRY.
*     Get the Persistent object for key
      lo_spfli_c = lo_spfli_a->create_persistent(
                      i_carrid = 'ZZ'
                      i_connid = '0017' ).
*
*     set the CITYFROM
      lo_spfli_c->set_cityfrom( 'NY' ).
*
*   Exception handling
    CATCH cx_root INTO lo_exc.
      MESSAGE lo_exc TYPE 'S'.
  ENDTRY.
*
* Required to coommit the changes to database
  COMMIT WORK.

You can check the standard program DEMO_CREATE_PERSISTENT.

Some facts:
- Singleton Design pattern is used for the Agent object in the agent class.
- We need to call the COMMIT WORK in order to update our changes into the database table
- If the entry doesn't exist in the database than resulting object of method GET_PERSISTENT would not be bound.

Persistent Object Services - Basics

2009-04-21T18:25:00.008-05:00

Some basics used in the Persistent Objects

Today we will see some basics about the Persistent Object Services.

Why do we need Persistent Object Service:
To better understand the need of the persistent objects we need to first understand the concept of the transient data. The local data for the program like Attributes of the class, or program data is known as the transient data.

Normally, with ABAP we load the data into our transient data, work on that and put it back to the database table (if required). At this point of time, our data exists in the two palces: Transient data (ABAP program local data) and in the appropriate database table or other storage medium (which is the persistent data). To avoid having the same data at the same time in two different context, we should use the persistent objects. Because by definition, the persistent data is the data which will be preserved beyound the runtime.

For SAP, we could have the persistent data in form of the Database table or file operations.

SAP Help defines the persistent objects like:

Technically speaking, ABAP Objects are always transient, just like the data objects in ABAP programs. There are no persistent objects in ABAP Objects. However, the Persistence Service within Object Services allows application developers to work with persistent objects. The Persistence Service can be thought of as a software layer between the ABAP program and the data repository (that is, the database), which allows you to save the attributes of objects with a unique identity, and then load them again when you need them.

Pros-&-Cons
- Good for big dialog / web applications where we are dealing with large number of data but for only one document at time like Sales Order processing, Process Order, GR creation etc.
- Adds one more abstraction layer in between the Business logic and the database.
- Not performance efficient for the report programming

How to create Persistent Objects
SAP Help on Mapping the Persistent Objects

Classes generated alongwith mapping:
When we finish up the creation of the persistent object services for any database table(s) it would create 2 additional classes. E.g: If we sucessfully map the table SPFLI in the Persistent Object class - ZCL_SPFLI_PERSISTENT, system would generate:
Actor Class - ZCA_SPFLI_PERSISTENT
Base Class - ZCB_SPFLI_PERSISTENT

In future posts, we would see how to use Persistent objects in application and some of its properties.

RFC Calls II - Solution to mandatory Parameters to FM

2009-04-20T20:29:00.005-05:00

In the last post RFC Calls: Function Module Parameter Passing, we have seen how system take care of the obligatory parameters even though the calling program doesn't pass it to the RFC FM.

Why does system needs to do that: Error handling. RFC FM can be called from outside SAP application also. If we don't pass the obligatory parameters, it would lead to runtime error of the missing obligatory parameters CALL_FUNCTION_PARM_MISSING. It could lead SAP System to errorenous status. It could become severe when we are dealing with the LUW - COMMIT WORK and ROLLBACK WORK.

This would raise an question: how do the programmer will design his code to make sure he got all the obligatory parameters filled in?

The simple solution would be: Create all the parameters as optional. Check all the parameters in the code with addition IF field IS NOT SUPPLIED and fill the return table with proper messages. This would notify the calling system that it didn't pass the obligatory parameters to execute the requested Function Module.

More reading on RFCs:
SAP Help - RFC
Master of the Five Remote Function Call (RFC) in ABAP

RFC Calls: Function Module Parameter Passing

2009-04-17T17:18:00.005-05:00

Parameter Passing in the RFC Function Module Calls

Today we will discuss how system take care of the obligatory parameter passing in the RFC function module.

Generally, when we call the FM without passing the obligatory parameter, system would raise the exception CALL_FUNCTION_PARM_MISSING and would lead to run time error. Now, when we call the same RFC FM with perticular Destination without passing the obligatory parameter, system is not giving any runtime error. How does this happen? Why this different behaviour?

Actually, when we generate our RFC FM, System generates one more Include program with Subroutine which calls the FM. So, when we call the RFC FM using CALL FUNCTION ... DESTINATION .. RFC Framework calls this generated Subroutine. This Subroutine passes all the parameters to the FM Call, including the obligatory ones and it is not giving us any runtime error of missing parameters.

To demonstrate this, I would use the RFC FM ZTEST_NP_RFC which was created in the FG ZTEST_NP. This is the code snippet for the RFC:

Code Snippet of the RFC Function Module

  
FUNCTION ztest_np_rfc.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     VALUE(KUNNR) TYPE  KUNNR
*"     VALUE(NAME1) TYPE  NAME1
*"  EXPORTING
*"     VALUE(SUBRC) TYPE  SUBRC
*"  EXCEPTIONS
*"      NO_DATA_FOUND
*"----------------------------------------------------------------------
*
* Both initial.. Return 3
* Else.. Return 4
  IF  kunnr IS INITIAL
  AND name1 IS INITIAL.
    subrc = '3'.
  ELSE.
    subrc = '4'.
  ENDIF.
*
ENDFUNCTION.

System has generated the Include LZTEST_NP_RFCV01 (L+fmname+V01) with subroutine ZTEST_NP_RFC (same name as the FM) which call the FM. This include is part of the RFC framework. Here is the code snippet for this include:

Code Snippet of the System Generated include LZTEST_NP_RFCV01

  
*******************************************************************
*   THIS FILE IS GENERATED BY THE FUNCTION LIBRARY               **
*   NEVER CHANGE IT MANUALLY, PLEASE!                            **
*******************************************************************
FORM ZTEST_NP_RFC %_RFC.
* Parameter declaration
DATA KUNNR TYPE
KUNNR
.
DATA NAME1 TYPE
NAME1
.
DATA SUBRC TYPE
SUBRC
.
* Assign default values
* Call remote function
  CALL FUNCTION 'ZTEST_NP_RFC' %_RFC
     EXPORTING
       KUNNR = KUNNR
       NAME1 = NAME1
     IMPORTING
       SUBRC = SUBRC
  .
ENDFORM.

Lets see the call to this FM:

Code Snippet to test RFC FM

  
REPORT  ztest_np_1 LINE-COUNT 10 NO STANDARD PAGE HEADING.
*
DATA: lf_subrc TYPE subrc.
*
START-OF-SELECTION.
*
* CALL RFC FM without passing the mandatory Parameters
*  and it would give us error
  CALL FUNCTION 'ZTEST_NP_RFC' DESTINATION 'NONE'
    IMPORTING
      subrc = lf_subrc.
*
  WRITE: lf_subrc.

Now, how do we find out how does this work? Since this is a part of the system, we need to activate the system debugging.
1. Put a breakpoint on the FM
2. Run the Program
3. From the debugger, start the System debugging. Settings > System Debugging
4. Step in (F5)
5. Check the Call the Stack

Have a look at the call stack

.. and the RFC Framework subroutine:

This would raise an question: As a developer, how do we design our RFC FMs which would not fail in terms of the functionality (works even we don't pass the mandatory parameters)? In next blog, we would explore why it behaves like this and how we can overcome the problem. You can find it here: RFC Calls II - Solution to mandatory Parameters to FM

SAPScript / SmartForms Custom Formatting

2009-04-02T19:08:00.003-05:00

In the previous post, we have seen how we can apply standard formatting options in the Smartform and SAPScripts. Today we will see, how we can create our own Formatting option which we can use in SAPScript or SmartForms.

There is lots of the similarity between Capital Oh "O" and the Zero "0" in the Output. So, business may wants to print the ZERO as the "Slashed Zero" like "Ø". Let's see how we can achieve to print the slashed Zero in our outputs.

For Smatforms, we can very well add the Program lines and convert all the Zeros to the slashed zero "Ø". But, it would be difficult to implement the same in the SAPScript using the PERFORM.

We can use the Conversion Routine to achieve this easily.
1. Create a Conversion Routine Function Modules:
For Conversion Routines, we need two FM - One for the Input & One for Output. E.g. If we want to create a conversion routine like ZZERO, then our conversion FMs would be: CONVERSION_EXIT_ZZERO_INPUT & CONVERSION_EXIT_ZZERO_OUTPUT.

To replace the zeros with the Slashed Zero, we need to implement the logic in the OUTPUT Conversion FM.

Code Snippet for CONVERSION_EXIT_ZZERO_OUTPUT

  
*&---------------------------------------------------------------------*
*& Importing
*&   value(INPUT) 
*& Exporting
*&   value(OUTPUT)
*&---------------------------------------------------------------------*
*
  OUTPUT = INPUT.
  REPLACE ALL OCCURRENCES OF '0' IN output WITH 'Ø'.

For the INPUT conversion FM, we really don't need any logic. So, we are just going to move the INPUT to OUTPUT.

Code Snippet for CONVERSION_EXIT_ZZERO_INPUT

  
*&---------------------------------------------------------------------*
*& Importing
*&   value(INPUT) 
*& Exporting
*&   value(OUTPUT)
*&---------------------------------------------------------------------*
*
  INPUT = OUTPUT.

2. Create a New Domain & assign the Conversion Routine. Like: create the domain name
ZZ_ZERO for the amount


 Data type        CURR
 No. characters       13
 Decimal places        2

 Output length        17
 Convers. routine ZZERO

3. Use this domain and create a data element.

Now, you can refer to this data element in your Smartform / SAPScript and it will print the '1ØØØ.1Ø' instead of the '1000.10'.

SAPScript / SmartForms Formatting Options

2009-04-01T17:37:00.005-05:00

There are so many standard formatting options avaliable in the SAPScript and SmartForms.

Refer to the document Formatting Symbols in SAPScript.

Marbles Game in ABAP

2009-03-10T19:09:00.010-05:00

Marbles Game, a fun and simple variation of the famous Chinese Checkers Game!

Aim:
Try to remove all but one marble from the board. You can remove a marble by skipping over it to an empty spot. Select a marble by clicking on it and move it by selecting the spot that you want to move to.

Look:
It looks like this:

Here is the code snippet for Marbles Game:

Code Snippet to change the Subtotal for Display & Print

 

*&---------------------------------------------------------------------*

*& Report  ZTEST_NP_MARBLE

*&

*&---------------------------------------------------------------------*

*&

*&

*&---------------------------------------------------------------------*

REPORT  ZTEST_NP_MARBLE NO STANDARD PAGE HEADING.

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

* I N C L U D E

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

INCLUDE <ICON>.

*

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

* D A T A   D E F I N I T I O N

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

*....Types

TYPES: BEGIN OF TY_SCORE,

SRL   TYPE I,

UNAME TYPE SY-UNAME,

SCORE TYPE I,

TIME  TYPE I,

END   OF TY_SCORE.

*....Internal Tables

DATA: BEGIN OF ITAB OCCURS 0,

C1,  C2,  C3,

C4,  C5,  C6,

C7,  C8,  C9,

END   OF ITAB.

DATA: BEGIN OF IT_PRINT OCCURS 0,

C1(4), C2(4), C3(4),

C4(4), C5(4), C6(4),

C7(4), C8(4), C9(4),

END   OF IT_PRINT.

DATA: IT_SCORE TYPE STANDARD TABLE OF TY_SCORE.

*....Work Areas

DATA: WA_ITAB  LIKE ITAB,

WA_PRINT LIKE IT_PRINT,

W_SCORE  TYPE TY_SCORE.

*....Globle Variables

DATA: L_NO_M      TYPE I,

L_NO_S      TYPE I,

L_NO_C      TYPE CHAR10,

L_HALF      TYPE I,

L_HALF_HALF TYPE I,

L_PRINT     TYPE FLAG,

L_NAME      TYPE CHAR20,

L_MOD       TYPE I.

DATA: W_ON        TYPE FLAG,

W_SEL_LINE  TYPE I,

W_SEL_COL   TYPE CHAR1,

W_DEST_OK   TYPE FLAG,

W_DEST_LINE TYPE I,

W_DEST_COL  TYPE CHAR1,

W_FIELD     TYPE CHAR20,

W_LINE      TYPE I,

W_GAME_OVER TYPE FLAG,

W_TOTAL     TYPE I,

W_REM       TYPE I,

W_GONE      TYPE I,

W_ST_TIME   TYPE I,

W_END_TIME  TYPE I,

W_EXPORTED  TYPE FLAG.

*....Field symbols

FIELD-SYMBOLS: <F> TYPE ANY.

*....Constants

CONSTANTS: ICON_0(40) TYPE C VALUE ICON_WD_RADIO_BUTTON_EMPTY,

ICON_1(40) TYPE C VALUE ICON_RADIOBUTTON,

ICON_2(40) TYPE C VALUE ICON_COLOR.

*.. Some systems don't have above listed ICONs You can use:

**....Constants

*CONSTANTS: ICON_0(40) TYPE C VALUE ICON_AVERAGE,      " ICON_WD_RADIO_BUTTON_EMPTY,

*           ICON_1(40) TYPE C VALUE ICON_POSITIVE,     " ICON_RADIOBUTTON,

*           ICON_2(40) TYPE C VALUE ICON_COLOR.

*

*....Ranges

RANGES: R_NOT_GREY FOR ABDOCMODE-FLAG.

*....Macros

DEFINE CONV_I_C.

&2 = &1.

CONDENSE &2.

END-OF-DEFINITION.

*

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

* S E L E C T I O N   S C R E E N

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

PARAMETERS: P_NUM TYPE I DEFAULT 7.

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

* A T   S E L E C T I O N - S C R E E N .

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

AT SELECTION-SCREEN.

IF  P_NUM GT 9

OR  P_NUM LT 5.

MESSAGE E398(00) WITH 'Currently allowed only: 5, 7, 9'.

ENDIF.

L_MOD = P_NUM MOD 2.

IF L_MOD = 0.

MESSAGE E398(00) WITH 'Only odd numbers are allowed'.

ENDIF.

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

* S T A R T   O F   S E L E C T I O N

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

START-OF-SELECTION.

GET TIME FIELD W_ST_TIME.

PERFORM FILL_MARBLES.

PERFORM FILL_PRINT_TABLE.

PERFORM WRITE_MARBLES.

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

* A T   L I N E   S E L E C T I O N

*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*

AT LINE-SELECTION.

GET CURSOR FIELD W_FIELD.

PERFORM CALCULATE_MARBLES.

PERFORM FILL_PRINT_TABLE.

SY-LSIND = 0.

PERFORM WRITE_MARBLES.

PERFORM CHECK_GAME_OVER.

*&---------------------------------------------------------------------*

*&      Form  fill_marbles

*&---------------------------------------------------------------------*

*       Fillup the initial table for the marbles

*----------------------------------------------------------------------*

FORM FILL_MARBLES .

* Grey cells

  L_HALF = FLOOR( P_NUM / 2 ).

L_HALF_HALF = L_HALF / 2.

R_NOT_GREY-SIGN   = 'I'.

R_NOT_GREY-OPTION = 'BT'.

R_NOT_GREY-LOW  = ( L_HALF - L_HALF_HALF ) + 1.

R_NOT_GREY-HIGH = ( L_HALF + L_HALF_HALF ) - 1.

APPEND R_NOT_GREY.

CLEAR  R_NOT_GREY.

* Filling up the table

  DO P_NUM TIMES.

L_NO_M = SY-INDEX.

NEW-LINE.

DO P_NUM TIMES.

L_NO_S = SY-INDEX.

CLEAR: L_PRINT.

IF L_NO_M IN R_NOT_GREY.

L_PRINT = 'X'.

ENDIF.

IF L_NO_S IN R_NOT_GREY.

L_PRINT = 'X'.

ENDIF.

IF L_PRINT = 'X'.

CONV_I_C L_NO_S L_NO_C.

CONCATENATE 'WA_ITAB-C' L_NO_C INTO L_NAME.

ASSIGN (L_NAME) TO <F>.

IF  L_NO_S = L_HALF

AND L_NO_M = L_HALF.

<F> = '0'.

W_TOTAL = W_TOTAL - 1.

ELSE.

<F> = '1'.

W_TOTAL = W_TOTAL + 1.

ENDIF.

ELSE.

WRITE: ' '.

ENDIF.

ENDDO.

APPEND WA_ITAB TO ITAB.

CLEAR  WA_ITAB.

ENDDO.

W_REM = W_TOTAL.

ENDFORM.                    " fill_marbles

*&---------------------------------------------------------------------*

*&      Form  fill_print_Table

*&---------------------------------------------------------------------*

*       Convert ITAB value to PRINT table value .

*----------------------------------------------------------------------*

FORM FILL_PRINT_TABLE .

FIELD-SYMBOLS: <F1> TYPE ANY.

REFRESH IT_PRINT.

LOOP AT ITAB INTO WA_ITAB.

L_NO_M = SY-INDEX.

DO P_NUM TIMES.

CONV_I_C SY-INDEX L_NO_C.

CLEAR L_NAME.

CONCATENATE 'WA_ITAB-C' L_NO_C INTO L_NAME.

ASSIGN (L_NAME) TO <F>.

CLEAR L_NAME.

CONCATENATE 'WA_PRINT-C' L_NO_C INTO L_NAME.

ASSIGN (L_NAME) TO <F1>.

CASE <F>.

WHEN '1'.

<F1> = ICON_1.

WHEN '0'.

<F1> = ICON_0.

WHEN '2'.

<F1> = ICON_2.

WHEN OTHERS.

ENDCASE.

ENDDO.

APPEND WA_PRINT TO IT_PRINT.

CLEAR  WA_PRINT.

ENDLOOP.

ENDFORM.                    " fill_print_Table

*&---------------------------------------------------------------------*

*&      Form  write_marbles

*&---------------------------------------------------------------------*

*       Write marbles from the PRINT table

*----------------------------------------------------------------------*

FORM WRITE_MARBLES .

FIELD-SYMBOLS: <F1> TYPE ANY.

IF W_GAME_OVER IS INITIAL.

LOOP AT IT_PRINT INTO WA_PRINT.

SKIP 1.

W_LINE = SY-TABIX.

WRITE: (2) W_LINE.

HIDE  W_LINE.

DO P_NUM TIMES.

CONV_I_C SY-INDEX L_NO_C.

CLEAR L_NAME.

CONCATENATE 'WA_PRINT-C' L_NO_C INTO L_NAME.

ASSIGN (L_NAME) TO <F1>.

IF NOT <F1> IS INITIAL.

WRITE: (2) <F1> AS ICON HOTSPOT ON, (2) ' '.

ELSE.

WRITE: (2) ' ', (2) ' '.

ENDIF.

ENDDO.

ENDLOOP.

ENDIF.

SKIP 4.

WRITE: /(30) 'Total Marbles:',    W_TOTAL.

WRITE: /(30) 'Remaining Marbles', W_REM.

SKIP 4.

PERFORM WRITE_5_HIGH_SCORE.

ENDFORM.                    " write_marbles

*&---------------------------------------------------------------------*

*&      Form  calculate_marbles

*&---------------------------------------------------------------------*

*       Calculate the marbles after the user input in line selection

*----------------------------------------------------------------------*

FORM CALCULATE_MARBLES .

* No marble has been selected

  IF W_ON IS INITIAL.

PERFORM VALIDATE_INPUT.

ELSE.

* remove the seleced marble

    PERFORM DESELECT_MARBLE.

IF W_ON = 'X'.

*     Check destination cell, if the same marble has not been selected

      PERFORM CHECK_DESTINATION.

ENDIF.

ENDIF.

* Destination is ok ..? rearrange the marbles in ITAB

  IF W_DEST_OK = 'X'.

PERFORM REARRANGE_MARBLES.

ENDIF.

ENDFORM.                    " calculate_marbles

*&---------------------------------------------------------------------*

*&      Form  validate_input

*&---------------------------------------------------------------------*

*       Validating the selected marble, is it movable or not

*       if marble is movable, highlight it

*----------------------------------------------------------------------*

FORM VALIDATE_INPUT .

DATA: L_SEL_FIELD(20),

L_TMP_FIELD(20),

L_SEL_COL(1),

L_TMP_COL(2),

L_TMP_LINE TYPE I,

L_OK TYPE FLAG.

FIELD-SYMBOLS: <F1> TYPE ANY,

<F2> TYPE ANY.

READ TABLE ITAB INTO WA_ITAB INDEX W_LINE.

L_SEL_FIELD = W_FIELD.

L_SEL_COL   = W_FIELD+10(1).

REPLACE 'PRINT' INTO L_SEL_FIELD WITH 'ITAB'.

CONDENSE L_SEL_FIELD.

ASSIGN (L_SEL_FIELD) TO <F1>.

* value = 0 >> No marble

  IF <F1> = '0'.

MESSAGE S398(00) WITH 'No marble to select.!'.

EXIT.

ENDIF.

* Check right

  L_TMP_COL = L_SEL_COL + 2.

IF L_TMP_COL < 9.

CONCATENATE 'WA_ITAB-C' L_TMP_COL INTO L_TMP_FIELD.

CONDENSE L_TMP_FIELD.

ASSIGN (L_TMP_FIELD) TO <F2>.

IF <F2> = '0'.

L_OK = 'X'.

ENDIF.

ENDIF.

* Check left

  IF L_OK IS INITIAL.

L_TMP_COL = L_SEL_COL - 2.

IF L_TMP_COL > 0.

CONCATENATE 'WA_ITAB-C' L_TMP_COL INTO L_TMP_FIELD.

CONDENSE L_TMP_FIELD.

ASSIGN (L_TMP_FIELD) TO <F2>.

IF <F2> = '0'.

L_OK = 'X'.

ENDIF.

ENDIF.

ENDIF.

* check Above

  IF L_OK IS INITIAL.

L_TMP_LINE = W_LINE - 2.

IF L_TMP_LINE > 0.

READ TABLE ITAB INTO WA_ITAB INDEX L_TMP_LINE.

IF <F1> = '0'.

L_OK = 'X'.

ENDIF.

READ TABLE ITAB INTO WA_ITAB INDEX W_LINE.

ENDIF.

ENDIF.

* Check underneath

  IF L_OK IS INITIAL.

L_TMP_LINE = W_LINE + 2.

IF L_TMP_LINE < 9.

READ TABLE ITAB INTO WA_ITAB INDEX L_TMP_LINE.

IF <F1> = '0'.

L_OK = 'X'.

ENDIF.

READ TABLE ITAB INTO WA_ITAB INDEX W_LINE.

ENDIF.

ENDIF.

* Ok .. than ON

  IF L_OK = 'X'.

W_ON = 'X'.

<F1> = '2'.

MODIFY ITAB FROM WA_ITAB INDEX W_LINE.

W_SEL_LINE = W_LINE.

W_SEL_COL  = L_SEL_COL .

ELSE.

MESSAGE S398(00) WITH 'No marble to select.!' ' ' ' ' ' '.

ENDIF.

ENDFORM.                    " validate_input

*&---------------------------------------------------------------------*

*&      Form  deselect_marble

*&---------------------------------------------------------------------*

*       Deselect the marble if the same marble is selected again

*----------------------------------------------------------------------*

FORM DESELECT_MARBLE .

DATA: L_SEL_FIELD(20).

FIELD-SYMBOLS: <F1> TYPE ANY.

READ TABLE ITAB INTO WA_ITAB INDEX W_LINE.

L_SEL_FIELD = W_FIELD.

REPLACE 'PRINT' INTO L_SEL_FIELD WITH 'ITAB'.

CONDENSE L_SEL_FIELD.

ASSIGN (L_SEL_FIELD) TO <F1>.

IF <F1> = '2'.

<F1> = '1'.

MODIFY ITAB FROM WA_ITAB INDEX W_LINE.

MESSAGE S398(00) WITH 'Marble was deselected..!!'.

CLEAR: W_ON, W_SEL_LINE, W_SEL_COL.

ENDIF.

ENDFORM.                    " deselect_marble

*&---------------------------------------------------------------------*

*&      Form  check_destination

*&---------------------------------------------------------------------*

*       Check the destination cell, it should not be empty and distnce

*       between selected cell and destination cell must be 2

*----------------------------------------------------------------------*

FORM CHECK_DESTINATION .

DATA: L_DEST_FIELD(20),

L_DEST_COL(1),

L_DEST_NOT_OK TYPE FLAG,

L_TMP_LINE TYPE I,

L_TMP_COL  TYPE C.

DATA: L_ITAB_DEST LIKE ITAB.

FIELD-SYMBOLS: <F1> TYPE ANY.

READ TABLE ITAB INTO L_ITAB_DEST INDEX W_LINE.

L_DEST_FIELD = W_FIELD.

L_DEST_COL   = W_FIELD+10(1).

REPLACE 'WA_PRINT' INTO L_DEST_FIELD WITH 'L_ITAB_DEST'.

CONDENSE L_DEST_FIELD.

ASSIGN (L_DEST_FIELD) TO <F1>.

* Destination should be empty

  IF <F1> <> '0'.

L_DEST_NOT_OK = 'X'.

ENDIF.

* Calcualate the distance between selected marble and destination

  IF L_DEST_NOT_OK IS INITIAL.

IF W_SEL_LINE <> W_LINE.

L_TMP_LINE = ABS( W_SEL_LINE - W_LINE ).

IF L_TMP_LINE <> '2'.

L_DEST_NOT_OK = 'X'.

ENDIF.

ENDIF.

ENDIF.

IF L_DEST_NOT_OK IS INITIAL.

IF W_SEL_COL <> L_DEST_COL.

L_TMP_COL = ABS( W_SEL_COL - L_DEST_COL ).

IF L_TMP_COL <> '2'.

L_DEST_NOT_OK = 'X'.

ENDIF.

ENDIF.

ENDIF.

* destination not ok

  IF L_DEST_NOT_OK = 'X'.

MESSAGE S398(00) WITH 'Destination is not GOOD' ' ' ' ' ' '.

ELSE.

W_DEST_OK = 'X'.

W_DEST_LINE = W_LINE.

W_DEST_COL  = L_DEST_COL.

ENDIF.

ENDFORM.                    " check_destination

*&---------------------------------------------------------------------*

*&      Form  rearrange_marbles

*&---------------------------------------------------------------------*

*       Rearrange marbles

*     1 Remove the marble which is inbetween the selected & destination

*     2 Remove the marble from the selected cell

*     3 Put marble on the destination cell

*----------------------------------------------------------------------*

FORM REARRANGE_MARBLES .

DATA: L_FIELD(20),

L_TMP_LINE TYPE I,

L_TMP_COL  TYPE CHAR1,

L_NO_MOVE  TYPE FLAG,

L_ITAB LIKE ITAB.

*

  FIELD-SYMBOLS: <F1> TYPE ANY.

* Make the inbetween column as 0 if both lines are same

  IF W_SEL_LINE = W_DEST_LINE.

IF W_SEL_COL > W_DEST_COL.

L_TMP_COL = W_DEST_COL + 1.

ELSE.

L_TMP_COL = W_SEL_COL + 1.

ENDIF.

READ TABLE ITAB INTO L_ITAB INDEX W_SEL_LINE.

L_FIELD = W_FIELD.

REPLACE 'WA_PRINT' INTO L_FIELD WITH 'L_ITAB'.

CONDENSE L_FIELD.

L_FIELD+8(1) = L_TMP_COL.

ASSIGN (L_FIELD) TO <F1>.

IF <F1> = 1.

<F1> = '0'.

W_GONE = W_GONE + 1.

MODIFY ITAB FROM L_ITAB INDEX W_SEL_LINE.

ELSE.

L_NO_MOVE = 'X'.

ENDIF.

CLEAR  L_ITAB.

ENDIF.

* Make the inbetween line as 0 if both lines are same

  IF W_SEL_COL = W_DEST_COL.

IF W_SEL_LINE > W_DEST_LINE.

L_TMP_LINE = W_DEST_LINE + 1.

ELSE.

L_TMP_LINE = W_SEL_LINE + 1.

ENDIF.

READ TABLE ITAB INTO L_ITAB INDEX L_TMP_LINE.

L_FIELD = W_FIELD.

REPLACE 'WA_PRINT' INTO L_FIELD WITH 'L_ITAB'.

CONDENSE L_FIELD.

L_FIELD+8(1) = W_SEL_COL.

ASSIGN (L_FIELD) TO <F1>.

IF <F1> = 1.

<F1> = '0'.

W_GONE = W_GONE + 1.

MODIFY ITAB FROM L_ITAB INDEX L_TMP_LINE.

ELSE.

L_NO_MOVE = 'X'.

ENDIF.

CLEAR  L_ITAB.

ENDIF.

IF L_NO_MOVE IS INITIAL.

*   Make Destination = 1

    READ TABLE ITAB INTO L_ITAB INDEX W_DEST_LINE.

L_FIELD = W_FIELD.

REPLACE 'WA_PRINT' INTO L_FIELD WITH 'L_ITAB'.

CONDENSE L_FIELD.

L_FIELD+8(1) = W_DEST_COL.

ASSIGN (L_FIELD) TO <F1>.

<F1> = '1'.

MODIFY ITAB FROM L_ITAB INDEX W_DEST_LINE.

CLEAR  L_ITAB.

*   Make Selected = 0.

    READ TABLE ITAB INTO L_ITAB INDEX W_SEL_LINE.

L_FIELD = W_FIELD.

REPLACE 'WA_PRINT' INTO L_FIELD WITH 'L_ITAB'.

CONDENSE L_FIELD.

L_FIELD+8(1) = W_SEL_COL.

ASSIGN (L_FIELD) TO <F1>.

<F1> = '0'.

MODIFY ITAB FROM L_ITAB INDEX W_SEL_LINE.

CLEAR  L_ITAB.

ELSE.

*   Make Selected = 1 when no movement

    READ TABLE ITAB INTO L_ITAB INDEX W_SEL_LINE.

L_FIELD = W_FIELD.

REPLACE 'WA_PRINT' INTO L_FIELD WITH 'L_ITAB'.

CONDENSE L_FIELD.

L_FIELD+8(1) = W_SEL_COL.

ASSIGN (L_FIELD) TO <F1>.

<F1> = '1'.

MODIFY ITAB FROM L_ITAB INDEX W_SEL_LINE.

CLEAR  L_ITAB.

ENDIF.

W_REM = W_TOTAL - W_GONE.

CLEAR: W_DEST_OK, W_DEST_LINE, W_DEST_COL,

W_ON,      W_SEL_LINE,  W_SEL_COL.

*

ENDFORM.                    " rearrange_marbles

*&---------------------------------------------------------------------*

*&      Form  check_game_over

*&---------------------------------------------------------------------*

*       Check game over when the remaining marbles are half than

*         the original marbles. Check for all cells with the marbles and

*         check adjacent cells (right, left, above and underneath cells)

*         with the value. If the marble found in any adjacent cell than

*         GAME is NOT OVER

*----------------------------------------------------------------------*

FORM CHECK_GAME_OVER .

STATICS: L_TOT_HALF TYPE I.

DATA: L_ITAB     LIKE ITAB,

L_ITAB_TMP LIKE ITAB.

DATA: L_TMP_FIELD(20),

L_SEL_COL(1),

L_TMP_COL(2),

L_OK       TYPE FLAG,

L_LINE     TYPE I,

L_TMP_LINE TYPE I.

CLEAR: L_OK.

FIELD-SYMBOLS: <F1> TYPE ANY,

<F2> TYPE ANY.

CHECK W_ON IS INITIAL.

L_TOT_HALF = ABS( W_TOTAL / 2 ).

CHECK W_REM < L_TOT_HALF.

LOOP AT ITAB INTO L_ITAB.

L_LINE = SY-TABIX.

L_ITAB_TMP = L_ITAB.

DO P_NUM TIMES.

L_ITAB = L_ITAB_TMP.

L_SEL_COL = SY-INDEX.

CONV_I_C SY-INDEX L_NO_C.

CLEAR L_NAME.

CONCATENATE 'L_ITAB-C' L_NO_C INTO L_NAME.

ASSIGN (L_NAME) TO <F1>.

IF <F1> IS INITIAL

OR <F1> = '0'.

CONTINUE.

ENDIF.

*      IF <F1> = '1'.

*        l_ok = 'X'.

*        exit.

*      ENDIF.

*     right neighbour

      L_TMP_COL = L_SEL_COL + 1.

IF L_TMP_COL < 9.

CONCATENATE 'L_ITAB-C' L_TMP_COL INTO L_TMP_FIELD.

CONDENSE L_TMP_FIELD.

ASSIGN (L_TMP_FIELD) TO <F2>.

IF <F2> = '1'.

L_TMP_COL = L_SEL_COL + 2.

IF L_TMP_COL < 9.

CONCATENATE 'L_ITAB-C' L_TMP_COL INTO L_TMP_FIELD.

CONDENSE L_TMP_FIELD.

ASSIGN (L_TMP_FIELD) TO <F2>.

IF <F2> = '0'.

L_OK = 'X'.

EXIT.

ENDIF.

ENDIF.

ENDIF.

ENDIF.

*     Check left

      L_TMP_COL = L_SEL_COL - 1.

IF L_TMP_COL > 0.

CONCATENATE 'L_ITAB-C' L_TMP_COL INTO L_TMP_FIELD.

CONDENSE L_TMP_FIELD.

ASSIGN (L_TMP_FIELD) TO <F2>.

IF <F2> = '1'.

L_TMP_COL = L_SEL_COL - 2.

IF L_TMP_COL > 0.

CONCATENATE 'L_ITAB-C' L_TMP_COL INTO L_TMP_FIELD.

CONDENSE L_TMP_FIELD.

ASSIGN (L_TMP_FIELD) TO <F2>.

IF <F2> = '0'.

L_OK = 'X'.

EXIT.

ENDIF.

ENDIF.

ENDIF.

ENDIF.

CONCATENATE 'L_ITAB-C' L_NO_C INTO L_TMP_FIELD.

CONDENSE L_TMP_FIELD.

ASSIGN (L_TMP_FIELD) TO <F2>.

*     check Above

      L_TMP_LINE = L_LINE - 1.

IF L_TMP_LINE > 0.

CLEAR L_ITAB.

READ TABLE ITAB INTO L_ITAB INDEX L_TMP_LINE.

IF <F2> = '1'.

L_TMP_LINE = L_LINE - 2.

IF L_TMP_LINE > 0.

CLEAR L_ITAB.

READ TABLE ITAB INTO L_ITAB INDEX L_TMP_LINE.

IF <F2> = '0'.

L_OK = 'X'.

EXIT.

ENDIF.

ENDIF.

ENDIF.

ENDIF.

*     Check underneath

      L_TMP_LINE = L_LINE + 1.

IF L_TMP_LINE < 9.

CLEAR L_ITAB.

READ TABLE ITAB INTO L_ITAB INDEX L_TMP_LINE.

IF <F2> = '1'.

L_TMP_LINE = L_LINE + 2.

IF L_TMP_LINE < 9.

CLEAR L_ITAB.

READ TABLE ITAB INTO L_ITAB INDEX L_TMP_LINE.

IF <F2> = '0'.

L_OK = 'X'.

EXIT.

ENDIF.

ENDIF.

ENDIF.

ENDIF.

ENDDO.

IF L_OK = 'X'.

EXIT.

ENDIF.

ENDLOOP.

IF L_OK IS INITIAL.

W_GAME_OVER = 'X'.

MESSAGE S398(00) WITH 'Game Over. Socre:' W_REM.

PERFORM EXPORT_HIGH_SCORE.

*    leave program.

  ENDIF.

ENDFORM.                    " check_game_over

*&---------------------------------------------------------------------*

*&      Form  export_high_score

*&---------------------------------------------------------------------*

*       Export High Score to memory when the game is over

*----------------------------------------------------------------------*

FORM EXPORT_HIGH_SCORE .

DATA: L_TIME TYPE I.

CHECK W_EXPORTED IS INITIAL.

GET TIME FIELD W_END_TIME.

L_TIME = W_END_TIME - W_ST_TIME.

W_SCORE-UNAME = SY-UNAME.

W_SCORE-SCORE = W_REM.

W_SCORE-TIME  = L_TIME.

APPEND W_SCORE TO IT_SCORE.

SORT IT_SCORE BY SCORE TIME.

LOOP AT IT_SCORE INTO W_SCORE.

W_SCORE-SRL = SY-TABIX.

MODIFY IT_SCORE FROM W_SCORE.

CLEAR  W_SCORE.

ENDLOOP.

DELETE IT_SCORE WHERE SRL > 5.

EXPORT IT_SCORE = IT_SCORE TO DATABASE INDX(ZZ)

ID 'ZGAME_MAR'.

W_EXPORTED = 'X'.

ENDFORM.                    " export_high_score

*&---------------------------------------------------------------------*

*&      Form  write_5_high_score

*&---------------------------------------------------------------------*

*       Write 5 high scores

*----------------------------------------------------------------------*

FORM WRITE_5_HIGH_SCORE .

IMPORT IT_SCORE = IT_SCORE FROM DATABASE INDX(ZZ)

ID 'ZGAME_MAR'.

WRITE: /(12) 'User',

(10) 'Score' RIGHT-JUSTIFIED ,

(10) 'Time'  RIGHT-JUSTIFIED.

WRITE: /(34) SY-ULINE.

LOOP AT IT_SCORE INTO W_SCORE.

WRITE: /(12) W_SCORE-UNAME,

(10) W_SCORE-SCORE,

(10) W_SCORE-TIME.

ENDLOOP.

ENDFORM.                    " write_5_high_score

Don't forget to share your high-scores in the comment.

Fun with ABAP

2009-03-10T18:52:00.003-05:00

In this section, you will find some Fun stuff with ABAP

ABAP Games

Marbles Game in ABAP
Truly, addictive Marbles Game created in ABAP.

Classical ALV: Change Subtotal - II for Print

2009-03-08T21:47:00.004-05:00

Change in the ALV Subtotal for the display & print

In the post, Classical ALV: Change Subtotal we have seen how we can change the Subtotal on the Classical ALV. Today, we will see how we can set the subtotal in the ALV display and the print function - Print Preview & Print.

We will use the event TOP_OF_LIST to perform this steps:

1. we need to get the ALV object form the ALV function module. We can use the FM GET_GLOBALS_FROM_SLVC_FULLSCR to get the Global data of the ALV. From this FM we will get the ALV object.

2. After getting the ALV object, we need to get the subtotal using the method GET_SUBTOTALS of the ALV object. We will get the first level subtotal using the parameter EP_COLLECT01.

3. Now, we need to modify the subtotal. Here we need to take help of Field-symbols since the EP_COLLECT01 is reference to data.

4. We need to refresh the Sub total in the print. For this purpose we will use the field-symbol to get an access the table (SAPLKKBL)IT_COLLECT01[]

Code snippet is like:

Code Snippet to change the Subtotal for Display & Print

  
REPORT  zalv_subtot_change.
*
*&---------------------------------------------------------------------*
*& Report  ZALV_SUBTOT_CHANGE.
*&
*&---------------------------------------------------------------------*
*& Program shows how to change the Subtotal of the classical ALV
*& check subroutine TOP_OF_PAGE
*&
*&---------------------------------------------------------------------*
*
TYPE-POOLS: slis.
*
TYPES: BEGIN OF ty_bkpf,
       belnr TYPE bkpf-belnr,
       buzei TYPE bseg-buzei,
       dmbtr TYPE bseg-dmbtr,
       per   TYPE bseg-dmbtr,
       per1  TYPE char10,
       mode  TYPE bapi_change_mode,
       END   OF ty_bkpf.
*
DATA: it_bkpf TYPE STANDARD TABLE OF ty_bkpf,
      it_bkpf1 TYPE STANDARD TABLE OF ty_bkpf,
      wa_bkpf TYPE ty_bkpf.
*
DATA: t_fieldcat   TYPE slis_t_fieldcat_alv.
DATA:  wa_fieldcat   TYPE slis_fieldcat_alv.
*
START-OF-SELECTION.
*
  SELECT belnr buzei dmbtr
         INTO TABLE it_bkpf
         FROM  bseg
         UP TO 20 ROWS.
*
  LOOP AT it_bkpf INTO wa_bkpf.
    wa_bkpf-per = 0.
    wa_bkpf-mode = 'O'.
    MODIFY it_bkpf FROM wa_bkpf.
    CLEAR  wa_bkpf.
  ENDLOOP.
*
  PERFORM create_field_catalog.
  PERFORM create_alv_output.
*
*&---------------------------------------------------------------------*
*&      Form  create_field_catalog
*&---------------------------------------------------------------------*
FORM create_field_catalog .
*
  PERFORM add_field_catalog USING :
    '01' 'BELNR'     'Doc'         '10'  '',
    '02' 'BUZEI'     'Line'        '3'  '',
    '03' 'DMBTR'     'Amount'      '17'  'X',
    '04' 'PER'       'Percentage'      '17'  'X',
    '05' 'PER1'      'Percentage'     '17'  '',
    '06' 'MODE'      'Mode'        '4'   ''.
*
ENDFORM.                    " create_field_catalog
*
*&---------------------------------------------------------------------*
*&      Form  add_field_catalog
*&---------------------------------------------------------------------*
*       Adds field details into field catalog
*----------------------------------------------------------------------*
FORM add_field_catalog  USING    p_colpos
                                 p_fldname
                                 p_fldtext
                                 p_outlen
                                 p_sum..
*
  wa_fieldcat-row_pos       = '1'.
  wa_fieldcat-col_pos       = p_colpos.
  wa_fieldcat-fieldname     = p_fldname.
  wa_fieldcat-tabname       = 'IT_BKPF'.
  wa_fieldcat-reptext_ddic  = p_fldtext.
  wa_fieldcat-outputlen     = p_outlen.
  wa_fieldcat-no_zero       = 'X'.  " <<
  wa_fieldcat-do_sum        = p_sum.
  IF wa_fieldcat-fieldname = 'MODE'.
    wa_fieldcat-rollname      = 'BAPI_CHANGE_MODE'.
  ENDIF.
  APPEND  wa_fieldcat TO t_fieldcat.
  CLEAR : wa_fieldcat.
*
ENDFORM.                    " add_field_catalog
*&---------------------------------------------------------------------*
*&      Form  create_alv_output
*&---------------------------------------------------------------------*
*       Generate ALV Grid output
*----------------------------------------------------------------------*
FORM create_alv_output .
  DATA: l_repid LIKE sy-repid,
        l_layout TYPE slis_layout_alv,
        l_print  TYPE  slis_print_alv.
*
  DATA: it_sort TYPE slis_t_sortinfo_alv,
        ls_sort TYPE slis_sortinfo_alv.
*
  DATA: it_filter TYPE slis_t_filter_alv,
        ls_filter TYPE slis_filter_alv.
*
  DATA: it_event_exit TYPE slis_t_event_exit,
        ls_event_exit TYPE slis_event_exit.
*
  DATA: t_event      TYPE slis_t_event,
        wa_event      TYPE slis_alv_event.
*
*
  l_repid = sy-repid.
*
  l_layout-no_totalline = 'X'.
  l_layout-colwidth_optimize = ' '.
*
  ls_sort-spos = '1'.
  ls_sort-fieldname = 'BUZEI'.
  ls_sort-tabname = 'IT_BKPF'.
  ls_sort-up = 'X'.
  ls_sort-subtot = 'X'.
  APPEND ls_sort TO it_sort.
*
*
  ls_event_exit-ucomm = '&ILT'.
  ls_event_exit-after = 'X'.
  APPEND ls_event_exit TO it_event_exit.
*
*
  CLEAR wa_event.
  wa_event-name = 'USER_COMMAND'.
  wa_event-form = 'USER_COMMAND'.
  APPEND wa_event TO t_event.
*
  CLEAR wa_event.
  wa_event-name = 'TOP_OF_PAGE'.
  wa_event-form = 'TOP_OF_PAGE'.
  APPEND wa_event TO t_event.
*
  CLEAR wa_event.
  wa_event-name = 'TOP_OF_LIST'.
  wa_event-form = 'TOP_OF_LIST'.
  APPEND wa_event TO t_event.
*
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      i_callback_program     = l_repid
      i_callback_top_of_page = 'TOP_OF_PAGE'
      is_layout              = l_layout
      is_print               = l_print
      it_sort                = it_sort
      it_filter              = it_filter
      it_fieldcat            = t_fieldcat[]
      it_events              = t_event
    TABLES
      t_outtab               = it_bkpf
    EXCEPTIONS
      program_error          = 1
      OTHERS                 = 2.
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
*
ENDFORM.                    " create_alv_output
*
*&---------------------------------------------------------------------*
*&      Form  TOP_OF_PAGE
*&---------------------------------------------------------------------*
FORM top_of_page.
*
  DATA: lo_grid TYPE REF TO cl_gui_alv_grid.
*
* get the global reference
  CALL FUNCTION 'GET_GLOBALS_FROM_SLVC_FULLSCR'
    IMPORTING
      e_grid = lo_grid.
*
* get the subtotal
  DATA: it_01 TYPE REF TO data.
*
  CALL METHOD lo_grid->get_subtotals
    IMPORTING
      ep_collect01 = it_01.
*
* change the data
  FIELD-SYMBOLS: <ft_tab> TYPE ANY TABLE,
                 <fs_tab> TYPE ANY,
                 <ff_field> TYPE ANY.
  ASSIGN it_01->* TO <ft_tab>.
*
  LOOP AT <ft_tab> ASSIGNING <fs_tab>.
    ASSIGN COMPONENT 'PER' OF STRUCTURE <fs_tab> TO <ff_field>.
    <ff_field> = '100'.
  ENDLOOP.
*
* Refresh the table display
  CALL METHOD lo_grid->refresh_table_display
    EXPORTING
      i_soft_refresh = 'X'.
*
ENDFORM.                    " top_of_page
*
*
*&---------------------------------------------------------------------*
*&      Form  TOP_OF_LIST
*&---------------------------------------------------------------------*
FORM top_of_list.
*
  DATA: lo_grid TYPE REF TO cl_gui_alv_grid.
*
* FOR Print out:
  CHECK sy-ucomm = 'PRIN'            " Print
  OR    sy-ucomm = '&RNT_PREV'.      " Print Preview
*
* get the global reference
  CALL FUNCTION 'GET_GLOBALS_FROM_SLVC_FULLSCR'
    IMPORTING
      e_grid = lo_grid.
*
* get the subtotal
  DATA: it_01 TYPE REF TO data.
*
  CALL METHOD lo_grid->get_subtotals
    IMPORTING
      ep_collect01 = it_01.
*
* change the data
  FIELD-SYMBOLS: <ft_tab> TYPE ANY TABLE,
                 <fs_tab> TYPE ANY,
                 <ff_field> TYPE ANY.
  ASSIGN it_01->* TO <ft_tab>.
*
  LOOP AT <ft_tab> ASSIGNING <fs_tab>.
    ASSIGN COMPONENT 'PER' OF STRUCTURE <fs_tab> TO <ff_field>.
    <ff_field> = '100'.
  ENDLOOP.
*
* Set the subtotal for the Print / Print preview
  FIELD-SYMBOLS: <fs_tab1> TYPE ANY TABLE.
  DATA: l_tab_name TYPE string.
*
  l_tab_name = '(SAPLKKBL)IT_COLLECT01[]'.
*
  ASSIGN (l_tab_name) TO <fs_tab1>.
  IF <fs_tab1> IS ASSIGNED.
*
    <fs_tab1> = <ft_tab>.
*
  ENDIF.
*
ENDFORM.                    " top_of_list

ABAP and Excel - Formatted Files with XML

2009-02-10T20:18:00.002-06:00

This is one of my published blogs on the SAP Community Network.

This blog show a way to generate the formatted excel files using the XML. From release 620, ABAP has provided us a way to transform our data using the XML transformation. We can very use the XML to generate the formatted Excel File.

Follow:
ABAP and Excel - Create Formatted Excel using XML

Generic Object Services (GOS) Toolbar Part 5 : Get Note attachment contents

2009-02-09T19:45:00.003-06:00

Shows how to get the contents of the NOTE attachements

In the previous post of this series we have seen:

Generic Object Services (GOS) Part 1 : Add New Option in the Toolbar

Generic Object Services (GOS) Part 2 : Handle added Service in the Toolbar

Generic Object Services (GOS) Part 3 : Add toolbar in Z program

Generic Object Services (GOS) Part 4 : Get Attachements

Today, we will see how to get the contents of the NOTE attachements.

Sometimes, we need to give the options for the attachement List when we design the some application with GOS toolbar. We will use the static method READ_LINKS from the class CL_BINARY_RELATION.

Code Snippet to Read the GOS attachments

  
*&---------------------------------------------------------------------*
*& Report  ZTEST_NP_GOS_ATT
*&
*&---------------------------------------------------------------------*
*& Read the GOS attachments
*&
*&---------------------------------------------------------------------*
*
REPORT  ztest_np_gos_note.
*
* Selection Screen
PARAMETERS: p_matnr TYPE mara-matnr.
*
*
START-OF-SELECTION.
*
*---------
* Get all the NOTE attached to Business object
*---------
*
* buseinss object key
  DATA: gs_lpor TYPE sibflporb.
*
  gs_lpor-instid = p_matnr.
  gs_lpor-typeid = 'BUS1001006'.
  gs_lpor-catid  = 'BO'.
*
* attachment type selection
  DATA: lt_relat TYPE obl_t_relt,
        la_relat LIKE LINE OF lt_relat.
*
  la_relat-sign = 'I'.
  la_relat-option = 'EQ'.
  la_relat-low = 'NOTE'.
  APPEND la_relat TO lt_relat.
*
* Read the links
  DATA: t_links TYPE obl_t_link,
        la_links LIKE LINE OF t_links.
*
  DATA: lo_root TYPE REF TO cx_root.
*
  TRY.
      CALL METHOD cl_binary_relation=>read_links
        EXPORTING
          is_object           = gs_lpor
          it_relation_options = lt_relat
        IMPORTING
          et_links            = t_links.
    CATCH cx_root INTO lo_root.
  ENDTRY.
*
*---------
* Read NOTE contents
*---------
  DATA l_folder_id TYPE soodk.
  DATA l_object_id TYPE soodk.
  DATA document_id       TYPE sofmk.
*
* Get document id
  READ TABLE t_links INTO la_links INDEX 1.
*
  document_id = la_links-instid_b.
*
* Set folder
  l_folder_id-objtp = document_id-foltp.
  l_folder_id-objyr = document_id-folyr.
  l_folder_id-objno = document_id-folno.
*
* Set Object
  l_object_id-objtp = document_id-doctp.
  l_object_id-objyr = document_id-docyr.
  l_object_id-objno = document_id-docno.
*
* Read the document content
  DATA document_content  TYPE STANDARD TABLE OF soli.
*
  CALL FUNCTION 'SO_OBJECT_READ'
    EXPORTING
      folder_id                  = l_folder_id
      object_id                  = l_object_id
    TABLES
      objcont                    = document_content
    EXCEPTIONS
      active_user_not_exist      = 1
      communication_failure      = 2
      component_not_available    = 3
      folder_not_exist           = 4
      folder_no_authorization    = 5
      object_not_exist           = 6
      object_no_authorization    = 7
      operation_no_authorization = 8
      owner_not_exist            = 9
      parameter_error            = 10
      substitute_not_active      = 11
      substitute_not_defined     = 12
      system_failure             = 13
      x_error                    = 14
      OTHERS                     = 15.
  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

To test this program:
Go to MM02
Enter Material and go to Basic data view 1
In GOS toolbar, Create > Note

Now, run the above program to get the attached NOTE contents.

Generic Object Services (GOS) Toolbar Part 4 : Get Attachements

2009-02-03T18:18:00.004-06:00

Shows how to get the Attachement details attached to the GOS toolbar

In the previous post of this series we have seen:

Generic Object Services (GOS) Part 1 : Add New Option in the Toolbar

Generic Object Services (GOS) Part 2 : Handle added Service in the Toolbar

Generic Object Services (GOS) Part 3 : Add toolbar in Z program

Today, we will see how to get the attachement details.

We will use the static method READ_LINKS from the class CL_BINARY_RELATION. We have to pass what kind of the objects we want to get back from the all the attachements like Notes, Attachment, External document etc.

This code will show how to get the NOTES attachments from the GOS toolbar.

Code Snippet to get the GOS attachments NOTES

   
*&---------------------------------------------------------------------*
*& Report  ZTEST_NP_GOS_ATT
*&
*&---------------------------------------------------------------------*
*& Read the GOS attachments
*&
*&---------------------------------------------------------------------*
*
REPORT  ztest_np_gos_note.
*
* Selection Screen
PARAMETERS: p_matnr TYPE mara-matnr.
*
*
START-OF-SELECTION.
*
*---------
* Get all the NOTE attached to Business object
*---------
*
* buseinss object key
  DATA: gs_lpor TYPE sibflporb.
*
  gs_lpor-instid = p_matnr.
  gs_lpor-typeid = 'BUS1001006'.
  gs_lpor-catid  = 'BO'.
*
* attachment type selection
  DATA: lt_relat TYPE obl_t_relt,
        la_relat LIKE LINE OF lt_relat.
*
  la_relat-sign = 'I'.
  la_relat-option = 'EQ'.
  la_relat-low = 'NOTE'. "For notes
  APPEND la_relat TO lt_relat.
*
* Read the links
  DATA: t_links TYPE obl_t_link,
        la_links LIKE LINE OF t_links.
*
  DATA: lo_root TYPE REF TO cx_root.
*
  TRY.
      CALL METHOD cl_binary_relation=>read_links
        EXPORTING
          is_object           = gs_lpor
          it_relation_options = lt_relat
        IMPORTING
          et_links            = t_links.
    CATCH cx_root INTO lo_root.
  ENDTRY.
*

To test this program:
Go to MM02
Enter Material and go to Basic data view 1
In GOS toolbar, Create > Note

Now, run the above program to get the attachment details.

The same way we can select attachements by adding the relation option ATTA.
Like:

Code Snippet to get the GOS attachments

   
*&---------------------------------------------------------------------*
  la_relat-sign = 'I'.
  la_relat-option = 'EQ'.
  la_relat-low = 'ATTA'.     "Attachements
  APPEND la_relat TO lt_relat.

Generic Object Services (GOS) Toolbar Part 3 : Add toolbar in Custom Program

2009-02-02T17:41:00.004-06:00

Shows the code for how to add Generic Object service Toolbar in the Z program

In the previous post of this series we have seen:

Generic Object Services (GOS) Part 1 : Add New Option in the Toolbar

Generic Object Services (GOS) Part 2 : Handle added Service in the Toolbar

Today, we will see how to get the GOS toolbar in the custom Report.

GOS toolbar works on the Business Object. To be able get GOS toolbar, we need to have a Business Object and Business Object Key. For example, to get the GOS toolbar for the customer, we need Business object KNA1 and customer number as the key. So, if we want to have a GOS toolbar in our custom transaction than we need to have a key before generating that. This is the reason; we don’t have the GOS toolbar option in the standard SAP Create transactions like: XD01, VA01, MM01 and so on.

This test program will provide us the GOS toolbar for the Customer in our custom program (Z program). This will provide us all the functionality of the GOS toolbar which are available in the XD02, XD03 transaction.

Code Snippet to Add GOS toolbar to Custom program

  
*&---------------------------------------------------------------------*
*& Report  ZTEST_NP_GOS
*&
*& To Generate GOS toolbar in the Custom Transaction
*&---------------------------------------------------------------------*
*
REPORT  ztest_np_gos.
*
DATA: lo_manager  TYPE REF TO cl_gos_manager,
      la_obj      TYPE borident.
*
PARAMETERS: p_kunnr TYPE kna1-kunnr.
*
*
START-OF-SELECTION.
*
* Set object Key
  la_obj-objtype = 'KNA1'.
  la_obj-objkey  = p_kunnr.
*
* GOS toolbar
  CREATE OBJECT lo_manager
    EXPORTING
      is_object    = la_obj
      ip_no_commit = space
    EXCEPTIONS
      OTHERS = 1.
*
* To generate output
  WRITE: 'GOS test for Customer'.

Now, we will get the GOS toolbar which will look like this:

Dynamic Internal Table

2008-12-23T20:32:00.005-06:00

Describes a way to create a dynamic internal table from coding. This is also can be used when RTTS is not supported or class CL_ALV_TABLE_CREATE is not available.

Previously, we have seen:

Dynamic Internal Table Creation using RTTS

Dynamic Internal Table with Deep structure using RTTS

Dynamic Internal Table creation using class CL_ALV_TABLE_CREATE

Recently, one of my friends asked me for the solution to create Internal Table. The problem was his system was not able to support the RTTS nor it has the class CL_ALV_TABLE_CREATE. Actually, I had developed this solution in early days when I was working on system 4.6B where I haven't RTTS nor the ALV class.

Here is the solution:

Code Snippet to Generate Dynamic ITAB

 
*&---------------------------------------------------------------------*
*& Report  ZDYN_ITAB_OLD
*&---------------------------------------------------------------------*
*& Fill the Subroutine Pool source
*& Generate Subroutine Pool
*& Call the Sobroutine to create ITAB
*&---------------------------------------------------------------------*
*
REPORT  zdyn_itab_old.
*
DATA: dy_table TYPE REF TO data,
      dy_line  TYPE REF TO data.
*
FIELD-SYMBOLS: <dyn_table> TYPE STANDARD TABLE,
               <dyn_wa>.
*
FIELD-SYMBOLS: <fs> TYPE ANY.
*
* To generate the Dyanmic table with the COLOR
DATA: ls_source TYPE string.
DATA: lt_source LIKE STANDARD TABLE OF ls_source WITH HEADER LINE.
*
DATA: l_name LIKE sy-repid.
DATA: l_message(240) TYPE c,
      l_line TYPE i,
      l_word(72) TYPE c.
*
DATA: l_form(30) TYPE c VALUE 'TABLE_CREATE'.
*
*.....................................................................
START-OF-SELECTION.
* Subroutine definition
  lt_source = 'REPORT ZTEST_SUBROUTINE_POOL.'.
  APPEND lt_source.
* From Begin
  lt_source = 'FORM  TABLE_CREATE USING I_FS TYPE ANY.'.
  APPEND lt_source.
* Table definition begin
  lt_source = 'DATA: BEGIN OF LT_GENTAB OCCURS 0.'.
  APPEND lt_source.
  lt_source = 'DATA: BUKRS TYPE BUKRS. '.
  APPEND lt_source.
  lt_source = 'DATA: BKTXT TYPE BKTXT. '.
  APPEND lt_source.
  lt_source = 'DATA: END OF LT_GENTAB.'.
  APPEND lt_source.
  lt_source = 'DATA: POINTER TYPE REF TO DATA.'.
  APPEND lt_source.
  lt_source = 'CREATE DATA POINTER LIKE STANDARD TABLE OF LT_GENTAB.'.
  APPEND lt_source.
  lt_source = 'I_FS = POINTER.'.
  APPEND lt_source.
* Form End
  lt_source = 'ENDFORM. '.
  APPEND lt_source.
*
* Subroutine Pool name
  l_name = 'ZTEST_SUBROUTINE_POOL'.
*
* Generate Subroutine
  CATCH SYSTEM-EXCEPTIONS generate_subpool_dir_full = 9.
    GENERATE SUBROUTINE POOL lt_source NAME l_name
             MESSAGE l_message LINE l_line WORD l_word."#EC CI_GENERATE
  ENDCATCH.
* Error handling
  IF NOT l_message IS INITIAL.
    MESSAGE e000(0k) WITH l_message l_line l_word.
  ENDIF.
*
* data reference
  ASSIGN dy_table TO <fs>.
* Call the subroutine
  PERFORM (l_form) IN PROGRAM (l_name) USING <fs>.
* Get the reference of the data and assign to field symbol
  ASSIGN dy_table->* TO <dyn_table>.
*
* Create dynamic work area and assign to FS
  CREATE DATA dy_line LIKE LINE OF <dyn_table>.
  ASSIGN dy_line->* TO <dyn_wa>.
*
*

SALV Table 10 - Editable SALV Model (Overcome the restriction of SALV Model)

2008-12-02T20:31:00.005-06:00

This is one of my published blog on the SAP Community Network.

In this blog, I described a way to overcome the restrictions of SALV models.

Follow:
Power of ABAP Objects: Overcome the Restrictions of SALV Model

This is only possible because of the power of the ABAP objects which gives us the access to the protected attributes in the derived child class.

Warning: Here I am trying to overcome the restriction and accessing the SALV attributes which SAP has not intented to expose to outside world and it made it protected. Read Thomas Jung's warning below the post.

Google Search Wiki - Suggestion & Comment about help-abap.blogspot.com

2008-11-24T19:14:00.007-06:00

Google SearchWiki allows users to give Suggestion and Votes to the Webpages

Google has started a new service called Google SearchWiki to give suggestion, votes annonate the web pages.

This is the screenshot generated by searching help-abap.blogspot.com in google.

Log in to your google account and test Google SearchWiki here for help-abap.blogspot.com and vote for your favourite blog.

Dynamic Internal Table Creation using class CL_ALV_TABLE_CREATE

2008-11-19T22:02:00.003-06:00

Describes how to show the Dynamic Internal Table Creation using class CL_ALV_TABLE_CREATE

In the post Dynamic Internal Table creation and Dynamic Internal Table with Deep Structure, we have seen how we can use the RTTS - Run Time Type Services to create dynamic internal table.

Today we will eloborate another way of creating the dynamic internal table. We will see how we can use the class CL_ALV_TABLE_CREATE to create a dynamic internal table for ALV.

Basic pricipal would be, we need to fill the field catalog table and pass it to static method CREATE_DYNAMIC_TABLE from class CL_ALV_TABLE_CREATE.

We will use the same example as the reference in the post Dynamic Internal Table creation.

Here is the code snippet:

Code Snippet to Display ALV output on the Selection Screen

 
 *&---------------------------------------------------------------------*
*& Report  ZTEST_NP_DYN
*& This Code snippet shows how to
*&   Create Dynamic Internal Table using the fieldcatalog and 
*&     class CL_ALV_TABLE_CREATE
*&   Dynamic Selection of data
*&   Accessing Dynamic data selection
*&   Displaying Dynamic internal table in ALV
*&---------------------------------------------------------------------*
*
REPORT  ztest_np_dyn.
*
DATA: lt_fieldcat TYPE lvc_t_fcat,
      la_fieldcat TYPE lvc_s_fcat,
      lo_table    TYPE REF TO data.
*
DATA: lf_months  TYPE monat,
      lf_run_mon TYPE monat.
*
* Dynamic Selection fields
TYPES: BEGIN OF ty_fields,
       field TYPE char30,
       END   OF ty_fields.
*
DATA:  lt_fields TYPE STANDARD TABLE OF ty_fields,
       la_fields TYPE ty_fields.
*
* field symbols to access the dynamic table
FIELD-SYMBOLS: <f_tab>   TYPE ANY TABLE,
               <f_line>  TYPE ANY,
               <f_field> TYPE ANY.
*
* Selection Screen
PARAMETERS: p_mon_fr TYPE monat,
            p_mon_to TYPE monat.
*
*
START-OF-SELECTION.
* 1. Adding fields in the field catalog
  la_fieldcat-fieldname = 'KSTAR'.
  la_fieldcat-datatype  = 'CHAR'.
  la_fieldcat-outputlen = 10.
  APPEND la_fieldcat TO lt_fieldcat.
  CLEAR  la_fieldcat.
*
* 2. Adding required fields based on the selection months
* Determining Number of fields
  lf_months = ( p_mon_to - p_mon_fr ) + 1.
  lf_run_mon = p_mon_fr.
*
  DO lf_months TIMES.
*   Field name
    CONCATENATE 'WTG0' lf_run_mon INTO la_fieldcat-fieldname.
    la_fieldcat-datatype  = 'CURR'.
    la_fieldcat-outputlen = 17.
*
*   Filling the fieldcatalog
    APPEND la_fieldcat TO lt_fieldcat.
    CLEAR  la_fieldcat.
*
    lf_run_mon = lf_run_mon + 1.
  ENDDO.
*
* Calling method to generate the dynamic internal table based on
* ALV field catalog
  cl_alv_table_create=>create_dynamic_table(
    EXPORTING
      it_fieldcatalog = lt_fieldcat
    IMPORTING
      ep_table = lo_table ).
*
  ASSIGN lo_table->* TO <f_tab>.
*
*$*$*...............Dynamic Selection.............................*$*$*
* Filling up the table for the Selection fields of Select Query
  LOOP AT lt_fieldcat INTO la_fieldcat.
    la_fields-field = la_fieldcat-fieldname.
    APPEND la_fields TO lt_fields.
    CLEAR: la_fieldcat, la_fields.
  ENDLOOP.
*
* Selecting data
  SELECT (lt_fields)
         INTO  TABLE <f_tab>
         FROM  cosp
         UP TO 10 ROWS.
*
*$*$*...............Accessing dynamic table.......................*$*$*
  LOOP AT <f_tab> ASSIGNING <f_line>.
    ASSIGN COMPONENT 'WTG004' OF STRUCTURE <f_line> TO <f_field>.
    <f_field> = '100.00'.
  ENDLOOP.
*
*$*$*...............Displaying using SALV model...................*$*$*
  DATA: lo_alv TYPE REF TO cl_salv_table.
*
  TRY.
      cl_salv_table=>factory(
        EXPORTING
          list_display = abap_false
        IMPORTING
          r_salv_table = lo_alv
        CHANGING
          t_table      = <f_tab> ).
    CATCH cx_salv_msg .
  ENDTRY.
*
  lo_alv->display( ).

I would suggest to use the RTTS to create dynamic internal table as depicted in posts:

Dynamic Internal Table Creation

Dynamic Internal Table with Deep structure

Generic Object Services (GOS) Toolbar Part 2 : Handle added Service in the Toolbar

2008-11-18T19:35:00.010-06:00

Describes the way to handle the added service in the Generic Object service Toolbar

As discussed in the post Generic Object Services (GOS) Toolbar Part 1 : Add New Option in the Toolbar, today we will see how to call our custom business logic in the added new Service in GOS Toolbar. To be able to process custom logic in the GOS toolbar service, we need to inherit out service class from the GOS generic service class CL_GOS_SERVICE and put our logic in the inherited class.

Steps to follow:
1. Inherit a class from the CL_GOS_SERVICE:

2. Maintain the Entry in the Table SGOSATTR as discussed in the Generic Object Services (GOS) Toolbar Part 1 : Add New Option in the Toolbar:

3. Redefine the Method EXECUTE to process our custom business logic. Redefine the Method and activate it. For demo purpose, we will not implement any logic in this but you can create a ALV or kind of list as we get in the Attachement List.

Now, when we access the GOS toolbar, you will see the option “Sales Order List”.

By accessing this option, you will get the empty screen like this:

You may have noticed that this Option is coming in all the GOS toolbars i.e. Toolbar in XD02 and XK02 and so on. To restrict the GOS toolbar service to only particular transaction, we need to redefine the method CHECK_STATUS.

Code snippet for the CHECK_STATUS method:

Code Snippet to Redefine CHECK_STATUS

 
*&---------------------------------------------------------------------*
*& Redefinition of the Method CHECK_STATUS
*&---------------------------------------------------------------------*
METHOD CHECK_STATUS.
* Service active for customer   IF IS_LPORB-TYPEID = 'KNA1'.
    EP_STATUS = MP_STATUS_ACTIVE.
  ELSE.
    EP_STATUS = MP_STATUS_INVISIBLE.
  ENDIF.
*
ENDMETHOD.

Now, we will only get the service only in the XD02 and XD03 transactions.

Generic Object Services (GOS) Toolbar Part 1 : Add New Option in the Toolbar

2008-10-30T18:37:00.013-05:00

Eloborates the option to add a new Menu Entry in the GOS toolbar

Generic Object Services (GOS) Toolbar offers the functions which are common to many SAP applications. This powerful toolbar provides much functionality like create attachments, notes, mails; send mails; list attachments and many more. You can find more functionality on Generic Object Services at SAP Help on Generic Object Services.

The default GOS toolbar options are somewhat like this:

Sometimes, we need to add some new toolbar entries to facilitate the business requirement. For example, in the Generic object toolbar add the new option like "Document List" which is generic to all business objects and of course we need to handle that. In this post, we will see the steps and rules to be followed to add a new Entry in the toolbar. In the next, post we will see how we can handle the added menu option to fulfill our custom requirement.

To be more specific in explaining the requirement, we will take a business requirement to add a new menu "Sales Orders List" for the GOS toolbar for Customer Master. At first we will see how we can just bring this menu option at very last position. Like:

To bring the new entry (menu option) in this GOS toolbar, we need to maintain that in the table SGOSATTR. This table can be maintained using SM30.

Class for Gen. Services: This is the driver class when we select the object service (menu option) from the GOS toolbar. For time being we will keep this as the CL_GOS_SRV_ATTACHMENT_LIST.
Service Type: We will select 1 because we want Single entry menu option on the GOS toolbar. There are options to create a main menu entry and submenus under that main menu by selecting proper service type.
Next Service: We will clear the value in this since we want our button at very last level. This next service field must be set when we need to put the custom option in between other options.
Control: We will select this, since we want to generate our output in the Custom Container.
Commit Work: We will not select this option because we don’t want to commit the work.

Along with creating a new entry this way, we need to set this service as next service of the previous service. In this case, our new service will come just under the "Help for object services" we need to modify that service like this:

By selecting this option Sales Orders list from the GOS toolbar, we will see the attachment list being generated by the class CL_GOS_SRV_ATTACHMENT_LIST:

NOTE: You might see the option grayed out if you don’t have any attachment created for that particular customer. To create: Select the Create.. > Create Attachment. Select any file from your PC to add as attachment.

To be able to bring that option in between of others, we need to play around with the Next Service value of the buttons. For example, I want to put my button just under the "Attachment List" option and above "Private Note".
For this we need to:
1.Set the new option as the next Service for the "Attachment List"

2.Set the “Private Note” as the next service for the new option

3.Remove the next service from the option which will come at last. This is very important.

After following these steps, the toolbar options will look like:

In the next post, we will see how we can use our custom class to generate our fully customized code i.e. Instead of the class CL_GOS_SRV_ATTACHMENT_LIST, we will use custom class ZCL_SO_LIST.

Display ALV report output in the SAME Selection Screen

2008-10-23T07:19:00.008-05:00

Shows the way to dispaly the report output in the same selection screen using Docking Container and SLAV 2D Table display with minimal coding

I was searching for the option to display the report output on the same selection-screen from quite a long time. SDN Forum thread How can i display output in the same selection screen reminded me again to research on this topic.

After a lot of analysis (and of course Trials-&-Errors), I found the solution which requires minimal development. Before giving the solution, check out how it looks-

When we start running the report, it will be a normal Selection Screen:

After executing the report, our output will overlay on the Selection Screen. And it will look like this:

Doesn't it look good ?

Journey to find the solution:
After reading the problem in the thread, suddenly I got a strike: Why not to create a Docking Container and place the ALV inside it..!!

I have started with placing the docking container in the INITIALIZATION event and the code to generate the ALV in the START-OF-SELECTION event. In this try, I got the docking container on the selection screen but no ALV inside of that docking container. Than I realize that I missed on of the basics of report programming - as soon as control goes to INITALIZATION all memory allocation will be destroyed and global data will be initialized. That's why I was not getting the ALV in the docking container. Selection screen was looking like this:

So, I moved the ALV logic in the INITALIZATION event. After this try, I got the Docking container with the empty ALV - ALV with the field catalog but no Data. Here again, I have the same problem - all my data allocation got destroyed as soon as control come to INITALIZATION event. To overcome this I used the ABAP local memory. I exported my output table and imported back it into the INITALIZATION to initialize my ALV. Selection-screen was looking like this:

Here is the code which will generate the output as shown in the second picture.

Code Snippet to Display ALV output on the Selection Screen

  
*&---------------------------------------------------------------------*
*& Generates the ALV on the Selection Screen itself
*&
*&---------------------------------------------------------------------*
REPORT  zalv_on_sel_screen.
*
*----------------------------------------------------------------------*
*  Local class for report
*----------------------------------------------------------------------*
CLASS lcl_report DEFINITION.
*
  PUBLIC SECTION.
*
    DATA: t_data   TYPE STANDARD TABLE OF sflight,  " Output dat
          r_carrid TYPE RANGE OF sflight-carrid.    " Select Option
*
    METHODS:
      get_data,
*
      generate_output.
*
ENDCLASS.                    "lcl_report DEFINITION
*
DATA: lo_report TYPE REF TO lcl_report.
*
DATA: w_carrid TYPE sflight-carrid.
*
** Selection Screen
SELECTION-SCREEN: BEGIN OF BLOCK blk1 WITH FRAME TITLE aaa.
SELECT-OPTIONS: s_carrid FOR w_carrid.
SELECTION-SCREEN: END   OF BLOCK blk1.
*
** Initialization
INITIALIZATION.
  aaa = 'Selection Criteria'.
* object for the report
  CREATE OBJECT lo_report.
* generate output
  lo_report->generate_output( ).
*
** Start of Selection
START-OF-SELECTION.
* Get data
  lo_report->r_carrid = s_carrid[].
  lo_report->get_data( ).
*
*----------------------------------------------------------------------*
* Local Class Implementation
*----------------------------------------------------------------------*
CLASS lcl_report IMPLEMENTATION.
*
  METHOD get_data.
*
*   data selection
    SELECT * FROM sflight
           INTO  TABLE me->t_data
           WHERE carrid IN s_carrid.
    IF sy-dbcnt IS INITIAL.
      MESSAGE s398(00) WITH 'No data selected'.
    ENDIF.
*
*   export to memory
    EXPORT data = me->t_data TO MEMORY ID sy-cprog.
*
  ENDMETHOD.                    "get_data
*
  METHOD generate_output.
*
*   local data
    DATA: lo_dock TYPE REF TO cl_gui_docking_container,
          lo_cont TYPE REF TO cl_gui_container,
          lo_alv  TYPE REF TO cl_salv_table.
*
*   import output table from the memory and free afterwards
    IMPORT data = me->t_data FROM MEMORY ID sy-cprog.
    FREE MEMORY ID sy-cprog.
*
*   Only if there is some data
    CHECK me->t_data IS NOT INITIAL.
*
*   Create a docking control at bottom
    CHECK lo_dock IS INITIAL.
    CREATE OBJECT lo_dock
      EXPORTING
        repid     = sy-cprog
        dynnr     = sy-dynnr
        ratio     = 80
        side      = cl_gui_docking_container=>dock_at_bottom
        name      = 'DOCK_CONT'.
    IF sy-subrc <> 0.
      MESSAGE 'Error in the Docking control' TYPE 'S'.
    ENDIF.
*
*   Create a SALV for output
    CHECK lo_alv IS INITIAL.
    TRY.
*       Narrow Casting: To initialize custom container from
*       docking container
        lo_cont ?= lo_dock.
*
*       SALV Table Display on the Docking container
        CALL METHOD cl_salv_table=>factory
          EXPORTING
            list_display   = if_salv_c_bool_sap=>false
            r_container    = lo_cont
            container_name = 'DOCK_CONT'
          IMPORTING
            r_salv_table   = lo_alv
          CHANGING
            t_table        = me->t_data.
      CATCH cx_salv_msg .
    ENDTRY.
*
*   Pf status
    DATA: lo_functions TYPE REF TO cl_salv_functions_list.
    lo_functions = lo_alv->get_functions( ).
    lo_functions->set_default( abap_true ).
*
*   output display
    lo_alv->display( ).
*
  ENDMETHOD.                    "generate_output
*
ENDCLASS.                    "lcl_report IMPLEMENTATION

Steps to create an ALV on the Selection Screen, in summary :

Create docking container in the INITALIZATION event

Create ALV on that Docking container

After selecting all the data, export output table to ABAP memory

Before generating the output, import the output table from the memroy

Call a New Standard Table Display (SE16N) from Report

2008-10-22T19:26:00.001-05:00

Shows another way to call the new Standard Table Display (SE16N), more efficient than calling SE16

As we have seen in the previous post, how easy it is to call the Standard Table Display from a report program. Today, we will see the more powerful and more efficient way to call the Table Display from the Report.

We will call the function module SE16N_INTERFACE to call the new standard table display.

Code Snippet to call SE16N from Report

   
*&---------------------------------------------------------------------*
*& Describes a way to call the SE16n with the Selection from report.
*&
*&---------------------------------------------------------------------*
*
REPORT  ztest_tmp.
*
START-OF-SELECTION.
*
* data declaration for the FM
  DATA: l_tab      TYPE se16n_tab,
        t_sel      TYPE se16n_or_t,
        la_sel     LIKE LINE OF t_sel,
        t_sel_tab  TYPE se16n_or_seltab_t,
        la_sel_tab LIKE LINE OF t_sel_tab.
*
* Table name
  l_tab = 'VBAK'.
*
* Selection for VBELN
  la_sel_tab-field   = 'VBELN'.
  la_sel_tab-sign    = 'I'.
  la_sel_tab-option  = 'BT'.
  la_sel_tab-low     = '0000001000'.
  la_sel_tab-high    = '0000002000 '.
  APPEND la_sel_tab TO t_sel_tab.
*
* Selection for ERDAT
  la_sel_tab-field   = 'ERDAT'.
  la_sel_tab-sign    = 'I'.
  la_sel_tab-option  = 'BT'.
  la_sel_tab-low     = '20081001'.
  la_sel_tab-high    = sy-datum.
  APPEND la_sel_tab TO t_sel_tab.
*
* Fill the main selection table
  la_sel-pos = 1.
  la_sel-seltab = t_sel_tab.
  APPEND la_sel TO t_sel.
*
* Function module for the SE16N
  CALL FUNCTION 'SE16N_INTERFACE'
    EXPORTING
      i_tab                  = l_tab
      i_clnt_dep             = 'X'
    TABLES
*     IT_OUTPUT_FIELDS       =
      it_or_selfields        = t_sel
    EXCEPTIONS
      no_values              = 1
      OTHERS                 = 2
            .
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

The output would be like:

As we can from the code, here we have passed the Actual Field name instead of the parameter name of the report program. This makes it more powerful and more efficient compare to standard table display using SE16.

Call Standard Table Display (SE16) from Report

2008-10-21T20:08:00.004-05:00

Eloborates the easiest way to call the Standard table display (SE16) from a Program

Sometimes, we need to call the Standard Table display (SE16) from our report program. In option of this we can create a Small ALV program using the New SALV model.

To call the Standard Table display, we can Submit the underlying program from our report. SAP creates a table dispaly report for all the database tables which can be viewed using the SE16. So, We can find that program name and Submit the program to call the Standard Table Display. This option does not seem to be the easiet way, as we have to find the underlying report name to call the SE16.

Let's explore another option. Trasaction SE16 internally calls the function module RS_TABLE_LIST_CREATE to generate the output. Why not we also call that from our program to call the SE16.

Here is the code snippet to call the SE16 using above said FM:

Code Snippet to call SE16

  
*&---------------------------------------------------------------------*
*& Describes a way to call the SE16 with the Selection from report.
*&
*&---------------------------------------------------------------------*
*
REPORT  ztest_tmp.
*
START-OF-SELECTION.
  DATA: t_sel TYPE STANDARD TABLE OF rsparams  WITH HEADER LINE.
*
* VBELN
  t_sel-selname = 'I1'.
  t_sel-kind    = ' '.
  t_sel-sign    = 'I'.
  t_sel-option  = 'BT'.
  t_sel-low     = '0000001000'.
  t_sel-high    = '0000002000'.
  APPEND t_sel.
  CLEAR  t_sel.
*
* ERDAT
  t_sel-selname = 'I2'.
  t_sel-kind    = ' '.
  t_sel-sign    = 'I'.
  t_sel-option  = 'BT'.
  t_sel-low     = '20081001'.
  t_sel-high    = sy-datum.
  APPEND t_sel.
*
* Function module to call the SE16 list
  CALL FUNCTION 'RS_TABLE_LIST_CREATE'
    EXPORTING
      table_name               = 'VBAK'
      action                   = 'ANZE'
*     WITHOUT_SUBMIT           = ' '
*     GENERATION_FORCED        =
*     NEW_SEL                  =
*     NO_STRUCTURE_CHECK       = ' '
*     DATA_EXIT                = ' '
*   IMPORTING
*     PROGNAME                 =
    TABLES
      seltab                   = t_sel
    EXCEPTIONS
      table_is_structure       = 1
      table_not_exists         = 2
      db_not_exists            = 3
      no_permission            = 4
      no_change_allowed        = 5
      OTHERS                   = 6
            .
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
             WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

It will generate an output somewhat like:

Disadvantages of SE16:
As we can see in the example code, instead of the Field name in the Selection Criteria table (T_SEL) we have to pass the Select Option name of the table selection screen. E.g. I1 for the Sales Document (VBELN) and I2 for the Creation Date (ERDAT). Sometimes, this Select-options may not present on the Selection screen when we call the SE16 and in that case we will not get the accurate result.

So, we will explore on how to call SE16N for the Standard Table display.

Print Table Control data (with header)

2008-10-20T21:04:00.008-05:00

Shows how to give an option to get a printout of the table control Data.

In SAP, we have a table control to give a felixibility to enter more than one record at a time. User enters the data and save it, inturn we save that data into the database - by direct update, or by using the BAPI or some data transfer mechanism.

Today we will show easy it is to give an option to print the data in the table control. Users will definatly like the option and you will get good Return-on-Investment. For this purpose, we will use the FM FITRV_PRINT_TABLE_CONTROL_DATA to get the print out. This FM internally calls the ALV FM go generate an output. So, by using this FM, we are not only getting the print option but we are getting all the standard ALV functionality like Filtering, Excel download, layout settings etc.

For my example, I have created a small table control which selects the data from the database and dispalys in the table control. I have provided an option to print that data by adding activating the GUI button of Print.

I have added my code which uses the FM FITRV_PRINT_TABLE_CONTROL_DATA to generate the ALV output which can be printed.

Code Snippet for printing Table Control Data

 
*&---------------------------------------------------------------------*
*&  Shows how to print the data from the table control
*&---------------------------------------------------------------------*
*       Prints the Table control data
*----------------------------------------------------------------------*
FORM print_table_control_data .
*
  DATA: l_callback TYPE sy-repid.
*
  l_callback = sy-repid.
*
  CALL FUNCTION 'FITRV_PRINT_TABLE_CONTROL_DATA'
    EXPORTING
      table_control                        = tc_data
      callback_program                     = l_callback
*     CALLBACK_TOP_OF_LIST                 =
      callback_top_of_page                 = 'TOP_OF_PAGE'
*     CALLBACK_END_OF_PAGE                 =
*     CALLBACK_END_OF_LIST                 =
      optimize_column_width                = 'X'
      get_curr_quan_fields_from_ddic       = 'X'
*     WINDOW_TITLE                         =
      print_immediately                    = ' '
    TABLES
      print_data                           = itab
    EXCEPTIONS
      column_information_missing           = 1
      printing_not_possible                = 2.
*
*
ENDFORM.                    " print_table_control_data
*
*&---------------------------------------------------------------------*
*    Generates the Top of page
*----------------------------------------------------------------------*
FORM top_of_page.
*
*** Top of page Report
  WRITE: / 'Sales Order report'.
*
ENDFORM.                    "top_of_page

When we press the button for the Print, it asks for the choice:

And by pressing the "Print Preview", we will get the output in ALV:

Oops, we don't have the header for this ALV output. I have debugged the FM FITRV_PRINT_TABLE_CONTROL_DATA and found out that this FM only determines the Field heading if we have created our table control with reference to the "Dictionary Table" !!! Since, we have already created a screen with appropriate logic, it is not advisable to change the table control to refer to the dictionary table. So, we need to find a way to change the Fieldcatalog when we call this FM with the table control created with reference to internal table.

To add the header in this output, we will use the FM REUSE_ALV_LIST_LAYOUT_INFO_GET to get the fieldcatalog of the ALV. We will modify that field catalog and use the FM REUSE_ALV_LIST_LAYOUT_INFO_SET to set the modified field catalog. We will use this logic in the subroutine which generates the TOP_OF_PAGE event.

Here is the code which we will use in the TOP_OF_PAGE subroutine to change the fieldcatalog of the ALV.

Code Snippet for the TOP-OF-PAGE to modify the field catalog

  
*&---------------------------------------------------------------------*
*    Generates the Top of page for the print
*    Also creates the column header in the print
*----------------------------------------------------------------------*
FORM top_of_page.
*
*** Top of page Report
  WRITE: / 'Sales Order report'.
*
*** Modify column headers
  DATA:   lt_slis_fcat TYPE slis_t_fieldcat_alv,
          la_fcat      LIKE LINE OF lt_slis_fcat.
*
* get the ALV field catalog from the ALV generated by the print
* FM FITRV_PRINT_TABLE_CONTROL_DATA
  CALL FUNCTION 'REUSE_ALV_LIST_LAYOUT_INFO_GET'
    IMPORTING
      et_fieldcat   = lt_slis_fcat
    EXCEPTIONS
      no_infos      = 1
      program_error = 2
      OTHERS        = 3.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
*
* Modify the Field catalog
  LOOP AT lt_slis_fcat INTO la_fcat.
    case la_fcat-fieldname.
      when 'VBELN'.  la_fcat-reptext_ddic = 'Sales Order'.
      when 'ERDAT'.  la_fcat-reptext_ddic = 'Create date'.
      when 'ERNAM'.  la_fcat-reptext_ddic = 'Created by'.
      when 'NETWR'.  la_fcat-reptext_ddic = 'Net Value'.
                     la_fcat-DATATYPE = 'DEC'.
    endcase.
    modify lt_slis_fcat from la_fcat.
  ENDLOOP.
*
* Set the field catalog information back to ALV
  CALL FUNCTION 'REUSE_ALV_LIST_LAYOUT_INFO_SET'
    EXPORTING
      it_fieldcat = lt_slis_fcat.
*
ENDFORM.                    "top_of_page

It will generate the output like:

ALV: Disable DELETE key on Keyboard in Classical ALV Grid

2008-10-18T19:21:00.002-05:00

Catch the event generated by DELETE-key on Keyboard & disable it in editable ALV generated using FM REUSE_ALV_GRID_DISPLAY

We have seen in the previous post how to Disable the DELETE-key in the keyboard in the editable ALV using the OO ALV class CL_GUI_ALV_GRID. Today, we will see how we can implement the same functionality using the classical ALV generated using the function module REUSE_ALV_GRID_DISPLAY.

As discussed in the previous post, to implement this we need to implement the DATA_CHANGED and the DATA_CHANGED_FINISHED event. The hurdle here is, we don't have a event similar to DATA_CHANGED_FINISHED in OOALV in the Classical FM REUSE_ALV_GRID_DISPLAY ALV.

Whenever we generate an ALV with the FM REUSE_ALV_GRID_DISPLAY, it internally creates a object reference fo the CL_GUI_ALV_GRID. We will get that object in our program to overcome the hurdle of not having the DATA_CHANGED_FINISHED event. We will get the OO ALV object from this ALV using the FM GET_GLOBALS_FROM_SLVC_FULLSCR. We will implement the event handler class for that ALV object.

Here I am giving the full example code snippet to implement this functionality.

Code Snippet to Disable DELETE key in the Classical ALV

 
*&---------------------------------------------------------------------*
*& Code snippet for diabling the delete key on the keyboard in the
*&   ALV created using FM REUSE_ALV_GRID_DISPLAY
*&---------------------------------------------------------------------*
REPORT ZALV_DIS_DEL_KEY.
*
TYPE-POOLS: slis.
* Data to be displayed
DATA: gt_sflight     TYPE TABLE OF sflight.
DATA: gt_sflight1    TYPE TABLE OF sflight,
      gs_layout      TYPE slis_layout_alv,
      l_deleted      TYPE flag.
*
DATA: o_grid TYPE REF TO cl_gui_alv_grid.
*
*----------------------------------------------------------------------*
* Event Handler class for ALV Events
*----------------------------------------------------------------------*
CLASS lcl_event_handle DEFINITION.
  PUBLIC SECTION.
    METHODS handle_data_changed
      FOR EVENT data_changed OF cl_gui_alv_grid
      IMPORTING er_data_changed.
*
    METHODS:
      handle_changed_finished FOR EVENT data_changed_finished
                             OF cl_gui_alv_grid
                             IMPORTING e_modified
                              et_good_cells.
*
ENDCLASS.                    "lcl_event_handle DEFINITION
*
DATA: o_event_h TYPE REF TO lcl_event_handle.
*
START-OF-SELECTION.
*---------------------------------------------------------------------*
* Selection
  SELECT * FROM sflight INTO CORRESPONDING FIELDS OF TABLE gt_sflight.
*
* Edit
  gs_layout-edit = 'X'.
*
* Event for Top-of-page
  DATA: lt_events TYPE slis_t_event.
  DATA: la_events LIKE LINE OF lt_events.
*
  la_events-name = 'TOP_OF_PAGE'.
  la_events-form = 'TOP_OF_PAGE'.
  APPEND la_events TO lt_events.
*
* Call ABAP List Viewer (ALV)
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      i_callback_program      = 'ZALV_DIS_DEL_KEY'
      i_callback_user_command = 'USER_COMMAND'
      i_structure_name        = 'SFLIGHT'
      is_layout               = gs_layout
      it_events               = lt_events
    TABLES
      t_outtab                = gt_sflight.
*
*&---------------------------------------------------------------------*
*      TOP-OF-PAGE. Also used to get the Object reference
*----------------------------------------------------------------------*
FORM top_of_page.
*
  DATA : lt_comment TYPE slis_t_listheader,
         la_comment TYPE slis_listheader.
*
* Top of page
  la_comment-typ  = 'H'.
  la_comment-info = 'Disabled Delete Key'.
  APPEND la_comment TO lt_comment.
*
* Commenty write
  CALL FUNCTION 'REUSE_ALV_COMMENTARY_WRITE'
    EXPORTING
      it_list_commentary = lt_comment.
*
* Get the ALV object
  CALL FUNCTION 'GET_GLOBALS_FROM_SLVC_FULLSCR'
    IMPORTING
      e_grid = o_grid.
*
* Register the Modified event ... Important
  CALL METHOD o_grid->register_edit_event
    EXPORTING
      i_event_id = cl_gui_alv_grid=>mc_evt_modified.
*
* Set Event handler
  CREATE OBJECT o_event_h.
  SET HANDLER o_event_h->handle_data_changed FOR o_grid.
  SET HANDLER o_event_h->handle_changed_finished FOR o_grid.
*
ENDFORM.                    "top_of_page
*
*&---------------------------------------------------------------------*
*       User Command
*----------------------------------------------------------------------*
FORM user_command USING r_ucomm TYPE sy-ucomm
                        rs_selfield TYPE slis_selfield.
  IF r_ucomm = '&DATA_SAVE'.
    MESSAGE 'You pressed the save button' TYPE 'I'.
  ENDIF.
ENDFORM.                    "user_command
*
*----------------------------------------------------------------------*
* Event Handler Class implementation
*----------------------------------------------------------------------*
CLASS lcl_event_handle IMPLEMENTATION.
*
  METHOD handle_data_changed.
*
*
    DATA: ls_deleted_rows LIKE LINE OF er_data_changed->mt_deleted_rows.
*
*   data is deleted or not. If yes, than fill the temporary table
*     to its copy
    DESCRIBE TABLE er_data_changed->mt_deleted_rows LINES sy-index.
    IF sy-index IS NOT INITIAL.
      l_deleted = 'X'.
      gt_sflight1[] = gt_sflight[].
      CLEAR er_data_changed->mt_deleted_rows.
    ENDIF.
*
*
  ENDMETHOD.                    "handle_data_changed
*
  METHOD  handle_changed_finished.
*
*   data has been deleted than set the temp data back to the main table
*   and refresh the table display
    IF l_deleted = 'X'.
      gt_sflight[] = gt_sflight1[].
      CLEAR: l_deleted, gt_sflight1.
    ENDIF.
*   message
    MESSAGE 'You can not delete any record' TYPE 'I'.
*   refresh the list display
    CALL METHOD o_grid->refresh_table_display
      EXCEPTIONS
        finished = 1
        OTHERS   = 2.
    IF sy-subrc NE 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
                 WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
*
  ENDMETHOD.                    "handle_changed_finished
*
ENDCLASS.                    "lcl_event_handle IMPLEMENTATION

Related post using FM GET_GLOBALS_FROM_SLVC_FULLSCR

Moving Cursor to Next row by pressing Enter in Classical ALV

Classical ALV: Change Subtotal

OO ALV: Disable DELETE key on Keyboard in ALV Grid

2008-10-16T20:25:00.010-05:00

Catch the event generated by DELETE-key on Keyboard & disable it in OO ALV using CL_GUI_ALV_GRID

From ABAP 6.20, SAP has provided many options with the ALV Grid created using the OO ALV using class CL_GUI_ALV_GRID. In the editable ALV, we can insert a new record, delete the record, modify the record and Save those records into database. Ofcourse, we have to write logic more all the process, expect the Delete record. Because records from the ALV grid can be deleted using the DELETE key on the keyboard..!!

Once in a while, we need to restrict this deletion. For this, we need to remove the option of delete from the ALV toolbar. This code will remove the option of Delete as well as the Insert from the toolbar.

Code Snippet

 
*&---------------------------------------------------------------------*
*& Code snippet for removing the delete button from the ALV toolbar in
*&   OO ALV created using CL_GUI_ALV 
*&---------------------------------------------------------------------*
*  Set the layout option to disable the option to insert or delete a
*  new row in from the input enable ALV
  data: ls_layout type LVC_S_LAYO.
  ls_layout-NO_ROWINS = 'X'.
  call method g_grid->SET_FRONTEND_LAYOUT
    exporting
      is_layout = ls_layout.

But still, records can be deleted with the DELETE key on keyboard. To avoid this we need to disable the DELETE key on the keyboard.

The solution, which I am going to provide will let the user delete the record, but we will give the message to user like "You can not delete..." and restore the data back. In order to achieve implement this solution, we need to:
1. Register the MODIFIED event for the Grid
2. Set the event handler for the events of the Grid DATA_CHANGED and DATA_CHANGED_FINISHED. We need to implement them also to get the deleted rows and insert them back into the main output table.

In the DATA_CHANGED event, we will be able to find if there are any records being deleted. In the DATA_CHANGED_FINISHED, we will set the data back from the temporary output table to main output table and Refresh the output.

Check out the code snippet:
1. Data declaration in the Global section

Code Snippet to add the deep component in Dynamic Itab

 *&---------------------------------------------------------------------*
*& Code snippet for diabling the delete key on the keyboard in the
*&   OO ALV created using CL_GUI_ALV
*&---------------------------------------------------------------------*
*1. Declare this data in global:
DATA:
* My existing table
gt_outtab   TYPE gs_outtab OCCURS 0 WITH HEADER LINE,
* Copy to hold temp data
gt_outtab1  TYPE gs_outtab OCCURS 0 WITH HEADER LINE.  "New copy table
*
DATA: l_deleted TYPE flag.

2. Implement the Events: DATA_CHANGED & DATA_CHANGED_FINISHED.

Code Snippet to add the deep component in Dynamic Itab

 *&---------------------------------------------------------------------*
*& Event Handler Defintion and Implementation
*&---------------------------------------------------------------------*
*
* Defintion of the Events: DATA_CHANGED & DATA_CHANGED_FINISHED.
CLASS lcl_event_receiver DEFINITION.
*
  PUBLIC SECTION.
    methods:
*    data change event
     handle_data_changed  FOR EVENT data_changed
                          OF cl_gui_alv_grid
                          IMPORTING er_data_changed,
*    data change finished event
     handle_changed_finished FOR EVENT data_changed_finished
                           OF cl_gui_alv_grid
                           IMPORTING e_modified
                            et_good_cells.
*
ENDCLASS.                    "lcl_event_receiver DEFINITION
*
* Implementation of events
CLASS lcl_event_receiver IMPLEMENTATION.
*
* This method gives us the data before delete.
* Parameter er_data_changed has the table which has the rows which are
* marked for delete or trying to delete it by pressing the delete button
  METHOD  handle_data_changed.
*
    DATA: ls_deleted_rows LIKE LINE OF er_data_changed->mt_deleted_rows.
*
*   data is deleted or not. If yes, than fill the temporary table to its copy
    DESCRIBE TABLE er_data_changed->mt_deleted_rows LINES sy-index.
    IF sy-index IS NOT INITIAL.
      l_deleted = 'X'.
      gt_outtab1[] = gt_outtab[].
      CLEAR er_data_changed->mt_deleted_rows.
    ENDIF.
*
  ENDMETHOD.                    "handle_data_changed
*
*
* data has been deleted than set the temp data back to the main table
* and refresh the table display
  METHOD handle_changed_finished.
*   restore data
    IF l_deleted = 'X'.
      gt_outtab[] = gt_outtab1[].
      CLEAR: l_deleted, gt_outtab1.
      REFRESH gt_outtab1.
    ENDIF.
*   refresh
    CALL METHOD g_grid->refresh_table_display
      EXCEPTIONS
        finished = 1
        OTHERS   = 2.
    IF sy-subrc  0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
                 WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
*
  ENDMETHOD.                    "handle_changed_finished
*
ENDCLASS.

3. Set Handler for those events before you set the table for display

Code Snippet to add the deep component in Dynamic Itab

 *&---------------------------------------------------------------------*
*& Set Event Handler for the ALV Grid
*&---------------------------------------------------------------------*
* Register the method
  CALL METHOD g_grid->register_edit_event
    EXPORTING
      i_event_id = cl_gui_alv_grid=>mc_evt_modified.
*
* Set event handler
  CREATE OBJECT g_event_receiver.
  SET HANDLER g_event_receiver->handle_data_changed FOR g_grid.
  SET HANDLER g_event_receiver->handle_changed_finished FOR g_grid.

In the next post, we will see how to implement this functionality in the ALV Grid created using the Function module.